
theorem
for f be PartFunc of REAL,REAL, x0,r be Real st
 f is_left_differentiable_in x0 & rng f = {r} holds Ldiff(f,x0) = 0
proof
    let f be PartFunc of REAL,REAL, x0,r be Real;
    assume that
A1:  f is_left_differentiable_in x0 and
A2:  rng f = {r};

A3: ex e be Real st e>0 & [.x0-e, x0.] c= dom f by A1,FDIFF_3:def 4;
    for h be non-zero 0-convergent Real_Sequence, c be constant Real_Sequence
     st rng c = {x0} & rng(h+c) c= dom f & (for n be Nat holds h.n<0) holds
     h"(#)(f/*(h+c) - f/*c) is convergent &
     lim (h"(#)(f/*(h+c) - f/*c)) = 0
    proof
     let h be non-zero 0-convergent Real_Sequence, c be constant Real_Sequence;
     assume that
A4:   rng c = {x0} and
A5:   rng(h+c) c= dom f and
A6:   for n be Nat holds h.n<0;
     thus
A7:   h"(#)(f/*(h+c) - f/*c) is convergent by A1,A4,A5,A6,FDIFF_3:def 4;

     consider e be Real such that
A8:   e > 0 & [.x0-e,x0.] c= dom f by A1,FDIFF_3:def 4;

     for p be Real st 0<p ex n be Nat st for m be Nat st n <= m holds
      |. (h"(#)(f/*(h+c) - f/*c)).m - 0 .| < p
     proof
      let p be Real;
      assume
A9:    0 < p;
      take n = 0;
      hereby let m be Nat;
       assume n <= m;

       x0-e < x0 by A8,XREAL_1:44; then
A10:    x0 in [.x0-e,x0.] by XXREAL_1:1; then
A11:    rng c c= dom f by A8,A4,ZFMISC_1:31;

A12:   f/*(h+c) = f*(h+c) & f/*c = f*c
         by A5,A10,A8,A4,ZFMISC_1:31,FUNCT_2:def 11;

A13:   dom(h+c) = NAT & dom c = NAT by FUNCT_2:def 1; then
       m in dom(h+c) & m in dom c by ORDINAL1:def 12; then
       m in dom(f*(h+c)) & m in dom(f*c)
         by A5,A10,A8,A4,ZFMISC_1:31,RELAT_1:27; then
       m in dom(f*(h+c)) /\ dom(f*c) by XBOOLE_0:def 4; then
A14:   m in dom( f*(h+c) - f*c ) by VALUED_1:12;

       (h+c).m in rng(h+c) & c.m in rng c
         by A13,ORDINAL1:def 12,FUNCT_1:3; then
       f.((h+c).m) in rng f & f.(c.m) in rng f by A5,A11,FUNCT_1:3; then
       f.((h+c).m) = r & f.(c.m) = r by A2,TARSKI:def 1; then
A15:   (f*(h+c)).m = r & (f*c).m = r by A13,ORDINAL1:def 12,FUNCT_1:13;

       (h"(#)(f/*(h+c) - f/*c)).m
        = (h").m * (f*(h+c) - f*c).m by A12,VALUED_1:5
       .= (h").m * ((f*(h+c)).m - (f*c).m) by A14,VALUED_1:13;
       hence |. (h"(#)(f/*(h+c) - f/*c)).m - 0 .| < p by A9,A15,COMPLEX1:44;
      end;
     end;
     hence lim (h"(#)(f/*(h+c) - f/*c)) = 0 by A7,SEQ_2:def 7;
    end;
    hence Ldiff(f,x0) = 0 by A3,FDIFF_3:9;
end;
