reserve y for set,
  x,a for Real,
  n for Element of NAT,
  Z for open Subset of REAL,
  f,f1,f2 for PartFunc of REAL,REAL;

theorem Th14:
  Z c= dom (exp_R*f) & (for x st x in Z holds f.x=-x) implies
  exp_R*f is_differentiable_on Z & for x st x in Z holds ((exp_R*f)`|Z).x = -
  exp_R(-x)
proof
  assume that
A1: Z c= dom (exp_R*f) and
A2: for x st x in Z holds f.x=-x;
A3: for x st x in Z holds f.x=(-1)*x+0
  proof
    let x;
    assume x in Z;
    then f.x=-x by A2
      .=(-1)*x+0;
    hence thesis;
  end;
  for y being object st y in Z holds y in dom f by A1,FUNCT_1:11;
  then
A4: Z c= dom f by TARSKI:def 3;
  then
A5: f is_differentiable_on Z by A3,FDIFF_1:23;
A6: for x st x in Z holds exp_R*f is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then f is_differentiable_in x by A5,FDIFF_1:9;
    hence thesis by TAYLOR_1:19;
  end;
  then
A7: exp_R*f is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((exp_R*f)`|Z).x = -exp_R(-x)
  proof
    let x;
    assume
A8: x in Z;
    then f is_differentiable_in x by A5,FDIFF_1:9;
    then diff(exp_R*f,x) = exp_R.(f.x)*diff(f,x) by TAYLOR_1:19
      .=exp_R.(f.x)*(f`|Z).x by A5,A8,FDIFF_1:def 7
      .=exp_R.(f.x)*(-1) by A4,A3,A8,FDIFF_1:23
      .=exp_R.(-x)*(-1) by A2,A8
      .=-exp_R.(-x)
      .=-exp_R(-x) by SIN_COS:def 23;
    hence thesis by A7,A8,FDIFF_1:def 7;
  end;
  hence thesis by A1,A6,FDIFF_1:9;
end;
