reserve E, x, y, X for set;
reserve A, B, C, D for Subset of E^omega;
reserve a, a1, a2, b, c, c1, c2, d, ab, bc for Element of E^omega;
reserve e for Element of E;
reserve i, j, k, l, n, n1, n2, m for Nat;

theorem Th14:
  A ^^ B = {<%>E} iff A = {<%>E} & B = {<%>E}
proof
  thus A ^^ B = {<%>E} implies A = {<%>E} & B = {<%>E}
  proof
    assume that
A1: A ^^ B = {<%>E} and
A2: A <> {<%>E} or B <> {<%>E};
    <%>E in A ^^ B by A1,TARSKI:def 1;
    then consider a, b such that
A3: a in A and
A4: b in B and
    <%>E = a ^ b by Def1;
A5: now
      let x;
      assume that
A6:   x in A or x in B and
A7:   x <> <%>E;
A8:   now
        assume
A9:     x in B;
        then reconsider xb = x as Element of E^omega;
A10:    a ^ xb <> <%>E by A7,AFINSQ_1:30;
        a ^ xb in A ^^ B by A3,A9,Def1;
        hence contradiction by A1,A10,TARSKI:def 1;
      end;
      now
        assume
A11:    x in A;
        then reconsider xa = x as Element of E^omega;
A12:    xa ^ b <> <%>E by A7,AFINSQ_1:30;
        xa ^ b in A ^^ B by A4,A11,Def1;
        hence contradiction by A1,A12,TARSKI:def 1;
      end;
      hence contradiction by A6,A8;
    end;
    then
A13: for x being object holds x in B iff x = <%>E by A4;
    for x being object holds x in A iff x = <%>E by A3,A5;
    hence contradiction by A2,A13,TARSKI:def 1;
  end;
  assume A = {<%>E} & B = {<%>E};
  hence thesis by Th13;
end;
