reserve p,p1,p2,q for Point of TOP-REAL 2,
  f,f1,f2,g,g1,g2 for FinSequence of TOP-REAL 2,
  r,s for Real,

  n,m,i,j,k for Nat,
  G for Go-board,
  x for set;
reserve f for non empty FinSequence of TOP-REAL 2;

theorem
  for n st n in dom f holds ex i,j st [i,j] in Indices GoB(f) & f/.n =
  GoB(f)*(i,j)
proof
  set x = X_axis(f), y = Y_axis(f);
  let n such that
A1: n in dom f;
A2: rng Incr(y) = rng y by SEQ_4:def 21;
  reconsider p=f/.n as Point of TOP-REAL 2;
A3: dom f = Seg len f by FINSEQ_1:def 3;
  dom y = Seg len y & len y = len f by FINSEQ_1:def 3,GOBOARD1:def 2;
  then y.n=p`2 & y.n in rng y by A1,A3,FUNCT_1:def 3,GOBOARD1:def 2;
  then consider j being Nat such that
A4: j in dom Incr(y) and
A5: Incr(y).j=p`2 by A2,FINSEQ_2:10;
A6: rng Incr(x) = rng x by SEQ_4:def 21;
  dom x = Seg len x & len x = len f by FINSEQ_1:def 3,GOBOARD1:def 1;
  then x.n=p`1 & x.n in rng x by A1,A3,FUNCT_1:def 3,GOBOARD1:def 1;
  then consider i being Nat such that
A7: i in dom Incr(x) and
A8: Incr(x).i=p`1 by A6,FINSEQ_2:10;
  width GoB(f)=card rng y & len Incr(y) = card rng y by Th13,SEQ_4:def 21;
  then
A9: Seg width GoB(f) = dom Incr(y) by FINSEQ_1:def 3;
  reconsider i,j as Element of NAT by ORDINAL1:def 12;
  take i,j;
  len GoB(f)=card rng x & len Incr(x) = card rng x by Th13,SEQ_4:def 21;
  then Indices GoB(f) = [:dom GoB(f), Seg width GoB(f):] & dom GoB(f) = dom
  Incr(x) by FINSEQ_3:29,MATRIX_0:def 4;
  hence [i,j] in Indices GoB(f) by A7,A4,A9,ZFMISC_1:87;
  then GoB(f)*(i,j) = |[p`1,p`2]| by A8,A5,Def1;
  hence thesis by EUCLID:53;
end;
