reserve i,j,k,i1,j1 for Nat,
  p for Point of TOP-REAL 2,
  x for set;
reserve f for non constant standard special_circular_sequence;

theorem
  for k st 1 <= k & k+2 <= len f for j,i st 1 <= j & j+1 <= width GoB f
& 1 <= i & i+2 <= len GoB f & f/.(k+1) = (GoB f)*(i+1,j) & (f/.k = (GoB f)*(i,j
) & f/.(k+2) = (GoB f)*(i+2,j) or f/.(k+2) = (GoB f)*(i,j) & f/.k = (GoB f)*(i+
2,j)) holds LSeg(1/2*((GoB f)*(i,j)+(GoB f)*(i+1,j+1)), 1/2*((GoB f)*(i+1,j)+(
  GoB f)*(i+2,j+1))) misses L~f
proof
  let k such that
A1: k >= 1 and
A2: k+2 <= len f;
A3: k+1+1 = k+(1+1);
  then k+1 < len f by A2,NAT_1:13;
  then
A4: LSeg(f,k+1) c= L~f & LSeg(f,k) = LSeg(f/.k,f/.(k+1)) by A1,TOPREAL1:def 3
,TOPREAL3:19;
  1 <= k+1 by NAT_1:11;
  then
A5: LSeg(f,k+1) = LSeg(f/.(k+1),f/.(k+2)) by A2,A3,TOPREAL1:def 3;
  let j,i such that
A6: 1 <= j and
A7: j+1 <= width GoB f and
A8: 1 <= i and
A9: i+2 <= len GoB f and
A10: f/.(k+1) = (GoB f)*(i+1,j) and
A11: f/.k = (GoB f)*(i,j) & f/.(k+2) = (GoB f)*(i+2,j) or f/.(k+2) = (
  GoB f)*(i,j) & f/.k = (GoB f)*(i+2,j);
A12: j < width GoB f by A7,NAT_1:13;
  i < i+2 by XREAL_1:29;
  then i <= len GoB f by A9,XXREAL_0:2;
  then
A13: L~f misses Int cell(GoB f,i,j) by A12,GOBOARD7:12;
  i+1 <= i+2 by XREAL_1:6;
  then
A14: i+1 <= len GoB f by A9,XXREAL_0:2;
  then L~f misses Int cell(GoB f,i+1,j) by A12,GOBOARD7:12;
  then
A15: L~f misses Int cell(GoB f,i,j) \/ Int cell(GoB f,i+1,j) by A13,XBOOLE_1:70
;
  i+1+1 = i+(1+1);
  then
A16: i+1 < len GoB f by A9,NAT_1:13;
  assume LSeg(1/2*((GoB f)*(i,j)+(GoB f)*(i+1,j+1)), 1/2*((GoB f)*(i+1,j)+(
  GoB f)*(i+2,j+1))) meets L~f;
  then
  L~f meets Int cell(GoB f,i,j) \/ Int cell(GoB f,i+1,j) \/ { 1/2*((GoB f
  )*(i+1,j)+(GoB f)*(i+1,j+1)) } by A6,A8,A16,A12,GOBOARD6:65,XBOOLE_1:63;
  then 1 <= i+1 & L~f meets { 1/2*((GoB f)*(i+1,j)+(GoB f)*(i+1,j+1)) } by A15,
NAT_1:11,XBOOLE_1:70;
  then consider k0 being Nat such that
  1 <= k0 and
  k0+1 <= len f and
A17: LSeg(f/.(k+1),(GoB f)*(i+1,j+1)) = LSeg(f,k0) by A6,A7,A10,A14,GOBOARD7:39
,ZFMISC_1:50;
  LSeg(f,k0) c= L~f & LSeg(f,k) c= L~f by TOPREAL3:19;
  hence contradiction by A6,A8,A10,A11,A16,A12,A17,A4,A5,GOBOARD7:61;
end;
