reserve f for non constant standard special_circular_sequence,
  i,j,k,i1,i2,j1,j2 for Nat,
  r,s,r1,s1,r2,s2 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board;

theorem Th13:
  i <= len G & j <= width G implies Int cell(G,i,j) <> {}
proof
  assume that
A1: i <= len G and
A2: j <= width G;
A3: j = width G or j < width G by A2,XXREAL_0:1;
A4: i = len G or i < len G by A1,XXREAL_0:1;
  set p = the Point of TOP-REAL 2;
  per cases by A3,A4,NAT_1:13,14;
  suppose 1 <= i & i+1 <= len G & 1 <= j & j+1 <= width G;
    then LSeg(1/2*(G*(i,j)+G*
    (i+1,j+1)),p) meets Int cell(G,i,j) by GOBOARD6:82;
    hence thesis;
  end;
  suppose 1 <= i & i+1 <= len G & j = width G;
    then LSeg(p,1/2*(G*(i,j)+G*(i+1,j))+|[0,1]|) meets Int cell(G,i,j)
    by GOBOARD6:83;
    hence thesis;
  end;
  suppose 1 <= i & i+1 <= len G & j = 0;
    then LSeg(1/2*(G*(i,j+1)+G*(i+1,j+1))- |[0,1]|,p) meets Int cell(G,i,j)
    by GOBOARD6:84;
    hence thesis;
  end;
  suppose 1 <= j & j+1 <= width G & i = 0;
    then LSeg(1/2*(G*(i+1,j)+G*(i+1,j+1))- |[1,0]|,p) meets Int cell(G,i,j)
    by GOBOARD6:85;
    hence thesis;
  end;
  suppose 1 <= j & j+1 <= width G & i = len G;
    then LSeg(p,1/2*(G*(i,j)+G*(i,j+1))+|[1,0]|) meets Int cell(G,i,j)
    by GOBOARD6:86;
    hence thesis;
  end;
  suppose i = 0 & j = 0;
    then LSeg(p,G*(i+1,j+1)- |[1,1]|) meets Int cell(G,i,j) by GOBOARD6:87;
    hence thesis;
  end;
  suppose i = len G & j = width G;
    then LSeg(p,G*(i,j)+|[1,1]|) meets Int cell(G,i,j) by GOBOARD6:88;
    hence thesis;
  end;
  suppose i = 0 & j = width G;
    then LSeg(p,G*(i+1,j)+|[-1,1]|) meets Int cell(G,i,j) by GOBOARD6:89;
    hence thesis;
  end;
  suppose i = len G & j = 0;
    then LSeg(p,G*(i,j+1)+|[1,-1]|) meets Int cell(G,i,j) by GOBOARD6:90;
    hence thesis;
  end;
end;
