reserve i,j,n,n1,n2,m,k,l,u for Nat,
        i1,i2,i3,i4,i5,i6 for Element of n,
        p,q for n-element XFinSequence of NAT,
        a,b,c,d,e,f for Integer;

theorem Th14:
  for P being INT -valued Polynomial of k+1,F_Real,a being Integer,
    n,i1,i2 st k+1 <= n & k in i2
  holds
    {p: for q being k+1-element XFinSequence of NAT st q = <%p.i2%>^(p|k) holds
            a* p.i1 = eval(P,@q)}
  is diophantine Subset of n -xtuples_of NAT
proof
  let P be INT -valued Polynomial of k+1,F_Real,a be Integer,n,i1,i2 such that
A1: k+1 <= n & k in i2;
  set k1=k+1;
  dom id k = k;
  then reconsider Idk=id k as XFinSequence by AFINSQ_1:5;
A2: len Idk=k;
A3: rng id k=Segm k;
  reconsider Idk as k-element XFinSequence of NAT by A2,CARD_1:def 7;
  reconsider nk=n-k1 as Nat by A1,NAT_1:21;
  set f = <%i2%>^Idk;
A4: rng <%i2%>={i2} by AFINSQ_1:33;
  {i2} misses k by A1,ZFMISC_1:50;
  then rng <%i2%> misses rng Idk by AFINSQ_1:33;
  then
A6: f is one-to-one by CARD_FIN:52;
  set R=rng f;
A7: len f = k1 by CARD_1:def 7;
A8: card dom f = k1 by CARD_1:def 7;
A:  k < n by A1,NAT_1:13;
  then
A9: Segm k c= Segm n by NAT_1:39;
  i2 in n by A1,SUBSET_1:def 1;
  then {i2} c= n by ZFMISC_1:31;
  then k \/ {i2} c= n by A9,XBOOLE_1:8;
  then
A10: R c= n by AFINSQ_1:26,A4,A3;
  then card (n\R) = (card n) - card R by CARD_2:44;
  then
A11: card (n\R) = nk by A8,A6,CARD_1:70;
A12: Segm k1 c= Segm n by A1,NAT_1:39;
  then
  card (n\k1) = card n-card k1 by CARD_2:44
    .= nk;
  then consider g be Function such that
A13: g is one-to-one & dom g =n\k1 & rng g = n\R
     by A11,CARD_1:5,WELLORD2:def 4;
A14: rng f misses rng g & dom f misses dom g by A7,A13,XBOOLE_1:79;
  then
A15: f +* g is one-to-one by A6,A13,FUNCT_4:92;
A16: dom (f+*g) = k1 \/ (n\k1) by A7,A13,FUNCT_4:def 1
      .= k1\/n by XBOOLE_1:39
      .= n by A12,XBOOLE_1:12;
A17: rng (f+*g) = R \/ rng g by A14,NECKLACE:6
      .= n \/ R by A13,XBOOLE_1:39
      .= n by A10,XBOOLE_1:12;
  then reconsider fg = f+*g as Function of n,n by A16,FUNCT_2:2;
  card n = card n;
  then fg is onto by A15,FINSEQ_4:63;
  then reconsider fg as Permutation of n by A15;
  defpred Q[XFinSequence of NAT] means
    for q be k1-element XFinSequence of NAT st q = ($1*fg)|k1 holds
      a*($1.i1) = eval(P,@q);
  defpred R[XFinSequence of NAT] means
    for q be k+1-element XFinSequence of NAT st q = <%$1.i2%>^($1|k) holds
      a*($1.i1) = eval(P,@q);
A18:for p be n-element XFinSequence of NAT holds Q[p] iff R[p]
  proof
    let p be n-element XFinSequence of NAT;
A19:  len p = n by CARD_1:def 7;
    then dom (p*fg)= n by A17,A16,RELAT_1:27;
    then reconsider pfg=p*fg as XFinSequence by AFINSQ_1:5;
    set I =<%p.i2%>;
    len pfg = n by A19,A17,A16,RELAT_1:27;
    then
A20:  len (pfg|k1) = k1 by A1,AFINSQ_1:54;
A21:  len (p|k)=k & len I=1 by AFINSQ_1:11,A,A19,CARD_1:def 7; then
A22:  len(I^(p|k)) = k1 by AFINSQ_1:17;
    for i st i in dom (I^(p|k)) holds (I^(p|k)).i = (pfg|k1).i
    proof
      let i; assume
A23:    i in dom (I^(p|k)); then
A24:    i in dom pfg & i in k1 & (pfg|k1).i = pfg.i
        by RELAT_1:57,FUNCT_1:47,A20,A22;
      then
A25:    pfg.i = p.(fg.i) & not i in dom g
        by FUNCT_1:12,A13,XBOOLE_1:79,XBOOLE_0:3;
      then
A26:    fg.i = f.i by FUNCT_4:11;
A27:  len <%i2%> = 1 by CARD_1:def 7;
      per cases by A23,AFINSQ_1:20;
      suppose
A28:      i in dom I;
        then i < len I =1 by AFINSQ_1:66,CARD_1:def 7;
        then i=0 & i in dom <%i2%> by CARD_1:def 7,A28,NAT_1:14;
        then f.i = <%i2%>.i =i2 & I.i = p.i2 by AFINSQ_1:def 3;
        hence thesis by A24,A25,A26,A28,AFINSQ_1:def 3;
      end;
      suppose ex j st j in dom (p|k) & i=len I+j;
        then consider j such that
A29:      j in dom (p|k) & i=len I+j;
A30:    (I^(p|k)).i = (p|k).j = p.j by A29,AFINSQ_1:def 3,FUNCT_1:47;
        j in dom Idk by A,A19,A29,AFINSQ_1:11;
        then f.i = Idk .j =j by A21,A27,A29,AFINSQ_1:def 3,FUNCT_1:17;
        hence thesis by A30,A24,A25,FUNCT_4:11;
      end;
    end;
    hence thesis by A20,A22,AFINSQ_1:8;
  end;
  {p: Q[p]} = {q: R[q]} from HILB10_3:sch 2(A18);
  hence thesis by Th13,A1;
end;
