reserve p1, p2 for Point of TOP-REAL 2,
  C for Simple_closed_curve,
  P for Subset of TOP-REAL 2;

theorem Th14:
  for T1,T2 being non empty TopSpace, f being Function of T1,T2 st
f is being_homeomorphism for A being Subset of T1, g being Function of T1|A, T2
  |(f.:A) st g = f|A holds g is being_homeomorphism
proof
  let T1,T2 be non empty TopSpace;
  let f be Function of T1,T2;
  assume that
A1: dom f = [#]T1 and
A2: rng f = [#]T2 and
A3: f is one-to-one and
A4: f is continuous and
A5: f" is continuous;
  let A be Subset of T1;
  f is onto by A2;
  then
A6: f qua Function" = f" by A3,TOPS_2:def 4;
  then
A7: f".:(f.:A) = f"(f.:A) by A3,FUNCT_1:85
    .= A by A1,A3,FUNCT_1:94;
A8: dom f = the carrier of T1 by FUNCT_2:def 1;
  let g be Function of T1|A, T2|(f.:A);
  assume
A9: g = f|A;
  [#](T1|A) = A & [#](T2|(f.:A)) = f.:A by PRE_TOPC:def 5;
  hence
A10: dom g = [#](T1|A) & rng g = [#](T2|(f.:A)) by A9,A8,RELAT_1:62,115;
A11: g is onto by A10;
  thus g is one-to-one by A3,A9,FUNCT_1:52;
  then
A12: g qua Function" = g" by A11,TOPS_2:def 4;
  thus g is continuous by A4,A9,Th13;
  g" = f"|(f.:A) by A3,A9,A6,A12,RFUNCT_2:17;
  hence thesis by A5,A7,Th13;
end;
