reserve x,x1,x2,y,z,z1 for set;
reserve s1,r,r1,r2 for Real;
reserve s,w1,w2 for Real;
reserve n,i for Element of NAT;
reserve X for non empty TopSpace;
reserve p,p1,p2,p3 for Point of TOP-REAL n;
reserve P for Subset of TOP-REAL n;

theorem Th14:
  for P being Subset of TOP-REAL n,a,b being Real, i st P =
{ p where p is Element of TOP-REAL n: a<p/.i & p/.i<b } & i in Seg n
  holds P is open
proof
  let P be Subset of TOP-REAL n,a,b be Real,i;
  assume that
A1: P = { p where p is Element of TOP-REAL n: a<p/.i & p/.i<b } and
A2: i in Seg n;
A3: P = { p1 :a<p1/.i} /\ {p2:p2/.i<b }
  proof
A4: { p1 :a<p1/.i} /\ {p2:p2/.i<b } c= P
    proof
      let x be object;
      assume
A5:   x in { p1 :a<p1/.i} /\ {p2:p2/.i<b };
      then x in {p2:p2/.i<b } by XBOOLE_0:def 4;
      then
A6:   ex p2 st x=p2 & p2/.i<b;
      x in { p1 :a<p1/.i} by A5,XBOOLE_0:def 4;
      then ex p1 st x=p1 & a<p1/.i;
      hence thesis by A1,A6;
    end;
    P c= { p1 :a<p1/.i} /\ {p2:p2/.i<b }
    proof
      let x be object;
      assume x in P;
      then
A7:   ex p3 st p3=x & a<p3/.i & p3/.i<b by A1;
      then
A8:   x in {p2:p2/.i<b };
      x in { p1 :a<p1/.i} by A7;
      hence thesis by A8,XBOOLE_0:def 4;
    end;
    hence thesis by A4,XBOOLE_0:def 10;
  end;
  { p:p/.i<b} c= the carrier of TOP-REAL n
  proof
    let x be object;
    assume x in { p:p/.i<b};
    then ex p st x= p & p/.i<b;
    hence thesis;
  end;
  then reconsider P2={ p:p/.i<b} as Subset of TOP-REAL n;
  { p:a<p/.i} c= the carrier of TOP-REAL n
  proof
    let x be object;
    assume x in { p:a<p/.i};
    then ex p st x= p & a<p/.i;
    hence thesis;
  end;
  then reconsider P1={ p:a<p/.i} as Subset of TOP-REAL n;
  P1 is open & P2 is open by A2,Th12,Th13;
  hence thesis by A3,TOPS_1:11;
end;
