reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;

theorem Th8:
  for A being Subset of TOP-REAL n, B being Subset of TOP-REAL n
  holds B is_outside_component_of A iff
  ex C being Subset of ((TOP-REAL n) | (A`))
  st C=B & C is a_component &
  C is not bounded Subset of Euclid n
proof
  let A be Subset of TOP-REAL n, B be Subset of TOP-REAL n;
A1: B is_a_component_of A` iff ex C being Subset of (TOP-REAL n) | (A`) st C=B
  & C is a_component by CONNSP_1:def 6;
  thus B is_outside_component_of A implies ex C being Subset of ((TOP-REAL n) |
  (A`)) st C=B & C is a_component & C is not bounded
  Subset of Euclid n
  proof
    reconsider D2=B as Subset of Euclid n by TOPREAL3:8;
    assume
A2: B is_outside_component_of A;
    then consider C being Subset of (TOP-REAL n) | (A`) such that
A3: C=B and
A4: C is a_component by A1;
    now
      assume for D being Subset of Euclid n st D=C holds D is bounded;
      then D2 is bounded by A3;
      hence contradiction by A2,Th5;
    end;
    hence thesis by A3,A4;
  end;
  given C being Subset of ((TOP-REAL n) | (A`)) such that
A5: C=B & C is a_component & C is not bounded
  Subset of Euclid n;
  ( not B is bounded)& B is_a_component_of A` by A5,Th5,CONNSP_1:def 6;
  hence thesis;
end;
