reserve p, q for Point of TOP-REAL 2,
  r for Real,
  h for non constant standard special_circular_sequence,
  g for FinSequence of TOP-REAL 2,
  f for non empty FinSequence of TOP-REAL 2,
  I, i1, i, j, k for Nat;

theorem Th14:
  for X being Subset of REAL st X = { q`2 : q`1 = E-bound L~h & q
in L~h } holds X = (proj2 | E-most L~h).:the carrier of (TOP-REAL 2)|(E-most L~
  h)
proof
  set T = (TOP-REAL 2)|(E-most L~h);
  set F = proj2 | E-most L~h;
  let X be Subset of REAL such that
A1: X = { q`2 : q`1 = E-bound L~h & q in L~h };
  thus X c= (proj2 | E-most L~h).:the carrier of T
  proof
    let x be object;
A2: dom F = the carrier of T by FUNCT_2:def 1
      .= [#] ((TOP-REAL 2)|(E-most L~h))
      .= E-most L~h by PRE_TOPC:def 5;
    assume x in X;
    then consider q1 being Point of TOP-REAL 2 such that
A3: q1`2 = x and
A4: q1`1 = E-bound L~h and
A5: q1 in L~h by A1;
A6: x = F.q1 by A3,A4,A5,PSCOMP_1:23,SPRECT_2:13;
A7: q1 in E-most L~h by A4,A5,SPRECT_2:13;
    then q1 in the carrier of T by A2,FUNCT_2:def 1;
    hence thesis by A2,A7,A6,FUNCT_1:def 6;
  end;
  thus (proj2 | E-most L~h).:the carrier of T c= X
  proof
    let x be object;
A8: E-most L~h c= L~h by XBOOLE_1:17;
    assume x in (proj2 | E-most L~h).:the carrier of T;
    then consider x1 be object such that
    x1 in dom F and
A9: x1 in the carrier of T and
A10: x = F.x1 by FUNCT_1:def 6;
    x1 in [#] ((TOP-REAL 2)|(E-most L~h)) by A9;
    then
A11: x1 in E-most L~h by PRE_TOPC:def 5;
    then reconsider x2 = x1 as Element of TOP-REAL 2;
A12: x2`1 = (E-min L~h)`1 by A11,PSCOMP_1:47
      .= E-bound L~h by EUCLID:52;
    x = x2`2 by A10,A11,PSCOMP_1:23;
    hence thesis by A1,A11,A12,A8;
  end;
end;
