reserve x,y for object,
  N for Element of NAT,
  c,i,j,k,m,n for Nat,
  D for non empty set,
  s for Element of 2Set Seg (n+2),
  p for Element of Permutations(n) ,
  p1, q1 for Element of Permutations(n+1),
  p2 for Element of Permutations(n +2),
  K for Field,
  a for Element of K,
  f for FinSequence of K,
  A for (Matrix of K),
  AD for Matrix of n,m,D,
  pD for FinSequence of D,
  M for Matrix of n,K;

theorem Th14:
  for i,j st i in Seg n & j in Seg n holds Delete(M,i,j)@ = Delete (M@,j,i)
proof
  let i,j such that
A1: i in Seg n and
A2: j in Seg n;
  n>0 by A1;
  then reconsider n1=n-1 as Element of NAT by NAT_1:20;
  set X1=Seg n;
  reconsider MT=M@ as Matrix of n,K;
  set D=Delete(M,i,j);
  set n9=n-'1;
  reconsider I=i as Element of NAT by ORDINAL1:def 12;
  reconsider DT=D@ as Matrix of n9,K;
  set D9=Delete(MT,j,i);
  set X=Seg n9;
A3: n1+1-'1=n1 by NAT_D:34;
  now
    n9<=n by NAT_D:35;
    then
A4: X c= X1 by FINSEQ_1:5;
    let k,m be Nat such that
A5: [k,m] in Indices DT;
    [m,k] in Indices D by A5,MATRIX_0:def 6;
    then
A6: DT*(k,m)=D*(m,k) by MATRIX_0:def 6;
    reconsider k9=k,m9=m as Element of NAT by ORDINAL1:def 12;
A7: Indices DT=[:X,X:] by MATRIX_0:24;
    then
A8: k in X by A5,ZFMISC_1:87;
    then
A9: k+1 in X1 by A3,FINSEQ_1:60;
A10: Indices M=[:X1,X1:] by MATRIX_0:24;
A11: m in X by A5,A7,ZFMISC_1:87;
    then
A12: m+1 in X1 by A3,FINSEQ_1:60;
    per cases;
    suppose
A13:  m9<I & k9<j;
      then
A14:  D9*(k,m)=MT*(k,m) by A1,A2,A8,A11,Th13;
A15:  [m,k] in Indices M by A8,A11,A4,A10,ZFMISC_1:87;
      D*(m,k)=M*(m,k) by A1,A2,A8,A11,A13,Th13;
      hence DT*(k,m)=D9*(k,m) by A6,A15,A14,MATRIX_0:def 6;
    end;
    suppose
A16:  m9<I & k9>=j;
      then
A17:  D9*(k,m)=MT*(k+1,m) by A1,A2,A8,A11,Th13;
A18:  [m,k+1] in Indices M by A11,A4,A9,A10,ZFMISC_1:87;
      D*(m,k)=M*(m,k+1) by A1,A2,A8,A11,A16,Th13;
      hence DT*(k,m)=D9*(k,m) by A6,A18,A17,MATRIX_0:def 6;
    end;
    suppose
A19:  m9>=I & k9<j;
      then
A20:  D9*(k,m)=MT*(k,m+1) by A1,A2,A8,A11,Th13;
A21:  [m+1,k] in Indices M by A8,A4,A12,A10,ZFMISC_1:87;
      D*(m,k)=M*(m+1,k) by A1,A2,A8,A11,A19,Th13;
      hence DT*(k,m)=D9*(k,m) by A6,A21,A20,MATRIX_0:def 6;
    end;
    suppose
A22:  m9>=I & k9>=j;
      then
A23:  D9*(k,m)=MT*(k+1,m+1) by A1,A2,A8,A11,Th13;
A24:  [m+1,k+1] in Indices M by A9,A12,A10,ZFMISC_1:87;
      D*(m,k)=M*(m+1,k+1) by A1,A2,A8,A11,A22,Th13;
      hence DT*(k,m)=D9*(k,m) by A6,A24,A23,MATRIX_0:def 6;
    end;
  end;
  hence thesis by MATRIX_0:27;
end;
