reserve X for non empty set;
reserve e,e1,e2,e19,e29 for Equivalence_Relation of X,
  x,y,x9,y9 for set;
reserve A for non empty set,
  L for lower-bounded LATTICE;

theorem Th14:
  for d being distance_function of A,L holds alpha d is meet-preserving
proof
  let d be distance_function of A,L;
  let a,b be Element of L;
  set f = alpha d;
A1: ex_inf_of f.:{a,b},EqRelLATT A by YELLOW_0:17;
  consider E3 being Equivalence_Relation of A such that
A2: E3 = f.(a "/\" b) and
A3: for x,y being Element of A holds [x,y] in E3 iff d.(x,y) <= a "/\" b
  by Def8;
  consider E2 being Equivalence_Relation of A such that
A4: E2 = f.b and
A5: for x,y being Element of A holds [x,y] in E2 iff d.(x,y) <= b by Def8;
  consider E1 being Equivalence_Relation of A such that
A6: E1 = f.a and
A7: for x,y being Element of A holds [x,y] in E1 iff d.(x,y) <= a by Def8;
A8: for x,y being Element of A holds [x,y] in E1 /\ E2 iff [x,y] in E3
  proof
    let x,y be Element of A;
    hereby
      assume
A9:   [x,y] in E1 /\ E2;
      then [x,y] in E2 by XBOOLE_0:def 4;
      then
A10:  d.(x,y) <= b by A5;
      [x,y] in E1 by A9,XBOOLE_0:def 4;
      then d.(x,y) <= a by A7;
      then d.(x,y) <= a "/\" b by A10,YELLOW_0:23;
      hence [x,y] in E3 by A3;
    end;
    assume [x,y] in E3;
    then
A11: d.(x,y) <= a "/\" b by A3;
    a "/\" b <= b by YELLOW_0:23;
    then d.(x,y) <= b by A11,ORDERS_2:3;
    then
A12: [x,y] in E2 by A5;
    a "/\" b <= a by YELLOW_0:23;
    then d.(x,y) <= a by A11,ORDERS_2:3;
    then [x,y] in E1 by A7;
    hence thesis by A12,XBOOLE_0:def 4;
  end;
A13: for x,y being object holds [x,y] in E1 /\ E2 iff [x,y] in E3
  proof
    let x,y be object;
    field E1 /\ field E2 = A /\ field E2 by EQREL_1:9
      .= A /\ A by EQREL_1:9
      .= A;
    then
A14: field (E1 /\ E2) c= A by RELAT_1:19;
    hereby
      assume
A15:  [x,y] in E1 /\ E2;
      then x in field (E1 /\ E2) & y in field (E1 /\ E2) by RELAT_1:15;
      then reconsider x9 = x, y9 = y as Element of A by A14;
      [x9,y9] in E3 by A8,A15;
      hence [x,y] in E3;
    end;
    assume
A16: [x,y] in E3;
    field E3 = A by EQREL_1:9;
    then reconsider x9 = x, y9 = y as Element of A by A16,RELAT_1:15;
    [x9,y9] in E1 /\ E2 by A8,A16;
    hence thesis;
  end;
  dom f = the carrier of L by FUNCT_2:def 1;
  then inf (f.:{a,b}) = inf {f.a,f.b} by FUNCT_1:60
    .= f.a "/\" f.b by YELLOW_0:40
    .= E1 /\ E2 by A6,A4,Th8
    .= f.(a "/\" b) by A2,A13,RELAT_1:def 2
    .= f.inf {a,b} by YELLOW_0:40;
  hence thesis by A1;
end;
