reserve x,y for set,
  i,j,k,l,m,n for Nat,
  K for Field,
  N for without_zero finite Subset of NAT,
  a,b for Element of K,
  A,B,B1,B2,X,X1,X2 for (Matrix of K),
  A9 for (Matrix of m,n,K),
  B9 for (Matrix of m,k,K);

theorem Th14:
  for V be VectSp of K for U be finite Subset of V for u, v be
Vector of V,a st u in U & v in U & (u = v implies (a <> -1_K or u = 0.V)) holds
  Lin (U \ {u} \/ {u+a*v}) = Lin U
proof
  let V be VectSp of K;
  let U be finite Subset of V;
  let u, v be Vector of V,a such that
A1: u in U and
A2: v in U and
A3: u = v implies (a <> -1_K or u = 0.V);
  set ua=u+a*v;
  set UU=U\{u};
  U c= the carrier of Lin (UU\/{ua})
  proof
    let x be object such that
A4: x in U;
    per cases;
    suppose
A5:   x=u;
      per cases;
      suppose
A6:     u<>v;
A7:     ua+(-a)*v = ua-a*v by VECTSP_1:21
          .= u+(a*v-a*v) by RLVECT_1:def 3
          .= u+0.V by VECTSP_1:16
          .= u by RLVECT_1:def 4;
        ua in {ua} by TARSKI:def 1;
        then ua in UU\/{ua} by XBOOLE_0:def 3;
        then
A8:     ua in Lin(UU\/{ua}) by VECTSP_7:8;
        v in UU by A2,A6,ZFMISC_1:56;
        then v in UU\/{ua} by XBOOLE_0:def 3;
        then (-a)*v in Lin(UU\/{ua}) by VECTSP_4:21,VECTSP_7:8;
        then ua+(-a)*v in Lin(UU\/{ua}) by A8,VECTSP_4:20;
        hence thesis by A5,A7,STRUCT_0:def 5;
      end;
      suppose
A9:     u=v;
        per cases by A3,A9;
        suppose
          a<>-1_K;
          then 0.K<> -1_K-a by VECTSP_1:19;
          then 0.K<> -(-1_K-a) by VECTSP_1:28;
          then
A10:      0.K<>a+1_K by VECTSP_1:31;
          ua in {ua} by TARSKI:def 1;
          then
A11:      ua in UU\/{ua} by XBOOLE_0:def 3;
          ua = 1_K*u+a*u by A9
            .= (1.K+a)*u by VECTSP_1:def 15;
          then (1.K+a)" *ua =u by A10,VECTSP_1:20;
          then u in Lin (UU\/{ua}) by A11,VECTSP_4:21,VECTSP_7:8;
          hence thesis by A5,STRUCT_0:def 5;
        end;
        suppose
          u=0.V;
          then x in Lin(UU\/{ua}) by A5,VECTSP_4:17;
          hence thesis by STRUCT_0:def 5;
        end;
      end;
    end;
    suppose
      x<>u;
      then x in UU by A4,ZFMISC_1:56;
      then x in UU\/{ua} by XBOOLE_0:def 3;
      then x in Lin (UU\/{ua}) by VECTSP_7:8;
      hence thesis by STRUCT_0:def 5;
    end;
  end;
  then Lin U is Subspace of Lin (UU\/{ua}) by VECTSP_9:16;
  then
A12: the carrier of Lin U c=the carrier of Lin (UU\/{ua}) by VECTSP_4:def 2;
  Lin (UU\/{ua}) is Subspace of Lin U by A1,A2,Th13;
  then the carrier of Lin (UU\/{ua})c= the carrier of Lin U by VECTSP_4:def 2;
  then the carrier of Lin U =the carrier of Lin (UU\/ {ua}) by A12;
  hence thesis by VECTSP_4:29;
end;
