reserve i, k, m, n for Nat,
  r, s for Real,
  rn for Real,
  x, y , z, X for set,
  T, T1, T2 for non empty TopSpace,
  p, q for Point of T,
  A, B, C for Subset of T,
  A9 for non empty Subset of T,
  pq for Element of [:the carrier of T,the carrier of T:],
  pq9 for Point of [:T,T:],
  pmet,pmet1 for Function of [:the carrier of T,the carrier of T:],REAL,
  pmet9,pmet19 for RealMap of [:T,T:] ,
  f,f1 for RealMap of T,
  FS2 for Functional_Sequence of [:the carrier of T,the carrier of T:],REAL,
  seq for Real_Sequence;

theorem Th14:
  for FS1 being Functional_Sequence of the carrier of T,REAL st (
for n ex f st FS1.n=f & f is continuous & for p holds f.p>=0) & (ex seq st seq
is summable & for n,p holds (FS1#p).n<=seq.n) for f st for p holds f.p=Sum(FS1#
  p) holds f is continuous
proof
  let FS1 be Functional_Sequence of the carrier of T,REAL such that
A1: for n ex f st FS1.n=f & f is continuous & for p holds f.p>=0 and
A2: ex seq st seq is summable & for n,p holds (FS1#p).n<=seq.n;
  let f such that
A3: for p holds f.p=Sum(FS1#p);
  reconsider fR=f as Function of T,R^1 by TOPMETR:17;
  now
    let p;
    for R being Subset of R^1 st R is open & fR.p in R ex U being Subset
    of T st U is open & p in U & fR.:U c= R
    proof
      reconsider fRp=fR qua real-valued Function.p as Point of RealSpace by
METRIC_1:def 13,XREAL_0:def 1;
      let R be Subset of R^1;
      assume R is open & fR.p in R;
      then consider rn such that
A4:   rn>0 and
A5:   Ball(fRp,rn) c= R by TOPMETR:15,def 6;
      set r2=rn/2,r4=rn/4;
      reconsider r2,r4 as Real;
A6:   r4>0 by A4,XREAL_1:224;
      consider seq such that
A7:   seq is summable and
A8:   for n,q holds (FS1#q).n<=seq.n by A2;
      Partial_Sums(seq) is convergent by A7,SERIES_1:def 2;
      then consider n such that
A9:   for m st n<=m holds |.Partial_Sums(seq).m-lim Partial_Sums(
      seq).|<r4 by A6,SEQ_2:def 7;
      defpred Sn[object,object] means
ex SS being Subset of T st SS = $2 & SS is
open & p in SS & for f1 st FS1.$1=f1 for f1p be Point of RealSpace st f1p=f1.p
      holds f1.:SS c= Ball(f1p,r2/(n+1));
A10:  for k being object st k in {0}\/Seg(n)
      ex U be object st U in bool the carrier of T & Sn[k,U]
      proof
        let k be object;
        assume k in {0}\/Seg(n);
        then k in Seg(n) or k in {0} by XBOOLE_0:def 3;
        then reconsider k as Element of NAT by TARSKI:def 1;
        consider f1 such that
A11:    FS1.k=f1 and
A12:    f1 is continuous and
        for p holds f1.p>=0 by A1;
        reconsider f19=f1 as Function of T,R^1 by TOPMETR:17;
        reconsider f1p=f19 qua real-valued Function.p as Point of RealSpace by
METRIC_1:def 13,XREAL_0:def 1;
        set B=Ball(f1p,r2/(n+1));
        reconsider B as Subset of R^1 by METRIC_1:def 13,TOPMETR:17;
        dist(f1p,f1p)=0 & r2>0 by A4,METRIC_1:1,XREAL_1:215;
        then dist(f1p,f1p)<r2/(n+1) by XREAL_1:139;
        then
A13:    f1p in B by METRIC_1:11;
        f19 is continuous by A12,JORDAN5A:27;
        then B is open & f19 is_continuous_at p by TMAP_1:50,TOPMETR:14,def 6;
        then consider U be Subset of T such that
A14:    U is open & p in U and
A15:    f19.:U c= B by A13,TMAP_1:43;
        for f1 st FS1.k=f1 for f1p be Point of RealSpace st f1p=f1.p
        holds f1.:U c= Ball(f1p,r2/(n+1)) by A11,A15;
        hence thesis by A14;
      end;
      consider FSn be Function of ({0}\/Seg(n)),bool the carrier of T such
      that
A16:  for k being object st k in {0}\/Seg(n) holds Sn[k,FSn.k] from
      FUNCT_2:sch 1(A10);
A17:  for k,q holds (FS1#q).k>=0
      proof
        let k,q;
        (ex f1 st FS1.k=f1 & f1 is continuous & for q holds f1.q >=0 )&
        FS1.k.q=( FS1#q).k by A1,SEQFUNC:def 10;
        hence thesis;
      end;
A18:  for k holds (seq^\(n+1)).k>=0
      proof
        let k;
        0<=(FS1#p).(n+1+k) & seq.(n+1+k)=(seq^\(n+1)).k by A17,NAT_1:def 3;
        hence thesis by A8;
      end;
      reconsider RNG=rng FSn as Subset-Family of T;
A19:  RNG is open
      proof
        let Q be Subset of T;
        assume Q in RNG;
        then consider x being object such that
A20:    x in dom FSn and
A21:    FSn.x=Q by FUNCT_1:def 3;
        ex SS being Subset of T st SS = FSn.x & SS is open & p in SS & for
f1 st FS1.x=f1 for f1p be Point of RealSpace st f1p=f1.p holds f1 .:SS c= Ball(
        f1p,r2/(n+1)) by A16,A20;
        hence thesis by A21;
      end;
      0 in {0} by TARSKI:def 1;
      then 0 in {0}\/Seg(n) by XBOOLE_0:def 3;
      then reconsider RNG as non empty Subset-Family of T by FUNCT_2:4;
A22:  lim Partial_Sums( seq ) =Sum(seq) & Sum(seq)=Partial_Sums(seq).n +
      Sum(seq^\ (n+1)) by A7,SERIES_1:15,def 3;
      |.Partial_Sums(seq).n-lim Partial_Sums(seq).|<r4 by A9;
      then |.-Sum(seq^\(n+1)).|<r4 by A22;
      then
A23:  |.Sum(seq^\(n+1)).|<r4 by COMPLEX1:52;
      seq^\(n+1) is summable by A7,SERIES_1:12;
      then Sum(seq^\(n+1))>=0 by A18,SERIES_1:18;
      then
A24:  Sum(seq^\(n+1))<r4 by A23,ABSVALUE:def 1;
A25:  for q holds FS1#q is summable & 0<=Sum((FS1#q)^\(n+1)) & Sum((FS1#q
      )^\(n+1))<r4
      proof
        let q;
        set F=FS1#q;
A26:    now
          let k;
A27:      seq.(n+1+k)= (seq^\(n+1)).k by NAT_1:def 3;
          0<=F.(n+1+k) & F.(n+1+k)<=seq.(n+1+k) by A8,A17;
          hence 0<=(F^\(n+1)).k & (F^\(n+1)).k<=(seq^\(n+1)).k by A27,
NAT_1:def 3;
        end;
A28:    for k holds 0<=F.k & F.k<=seq.k by A8,A17;
        then F is summable by A7,SERIES_1:20;
        then
A29:    F^\(n+1) is summable by SERIES_1:12;
        seq^\(n+1) is summable by A7,SERIES_1:12;
        then Sum(F^\(n+1))<=Sum(seq^\(n+1)) by A26,SERIES_1:20;
        hence thesis by A7,A24,A28,A26,A29,SERIES_1:18,20,XXREAL_0:2;
      end;
A30:  fR.:(meet RNG)c=R
      proof
        let fRq be object;
        assume fRq in fR.:(meet RNG);
        then consider q be object such that
A31:    q in dom fR and
A32:    q in meet RNG and
A33:    fRq=fR.q by FUNCT_1:def 6;
        reconsider q as Point of T by A31;
        set sp=FS1#p, sq=FS1#q, spn=sp^\(n+1), sqn=sq^\(n+1);
        set absPSpq=Partial_Sums(|.sp-sq.|);
        for k st k<=n holds (|.sp-sq.|).k <=r2/(n+1)
        proof
          let k such that
A34:      k<=n;
          k=0 or k>=1 by NAT_1:14;
          then k in {0} or k in Seg n by A34,FINSEQ_1:1,TARSKI:def 1;
          then
A35:      k in {0}\/Seg n by XBOOLE_0:def 3;
          then FSn.k in RNG by FUNCT_2:4;
          then
A36:      q in FSn.k by A32,SETFAM_1:def 1;
A37: k in NAT by ORDINAL1:def 12;
          dom (sp-sq)= NAT by FUNCT_2:def 1;
          then
A38:      (sp-sq).k=sp.k-sq.k by VALUED_1:13,A37;
          consider f1 such that
A39:      FS1.k=f1 and
          f1 is continuous and
          for p holds f1.p>=0 by A1;
          reconsider f1p=f1.p,f1q=f1.q as Point of RealSpace by METRIC_1:def 13
;
          ex SS being Subset of T st SS = FSn.k & SS is open & p in SS &
for f1 st FS1.k=f1 for f1p be Point of RealSpace st f1p=f1.p holds f1 .:SS c=
          Ball(f1p,r2/(n+1)) by A16,A35;
          then
A40:      f1.:(FSn.k) c= Ball(f1p,r2/(n+1)) by A39;
          dom f1=the carrier of T by FUNCT_2:def 1;
          then f1q in f1.:(FSn.k) by A36,FUNCT_1:def 6;
          then dist(f1p,f1q)<r2/(n+1) by A40,METRIC_1:11;
          then
A41:      |.f1.p-f1.q.|<r2/(n+1) by TOPMETR:11;
          f1.p=sp.k by A39,SEQFUNC:def 10;
          then |.sp.k-sq.k.|<r2/(n+1) by A39,A41,SEQFUNC:def 10;
          hence thesis by A38,SEQ_1:12;
        end;
        then
A42:    absPSpq.n <=(r2/(n+1))*(n+1) by Th12;
A43: n in NAT by ORDINAL1:def 12;
        set PSp=Partial_Sums(sp),PSq=Partial_Sums(sq),PSpq=Partial_Sums(sp-sq);
        PSp-PSq=PSpq & dom (PSp-PSq)= NAT by SEQ_1:1,SERIES_1:6;
        then
A44:    |.PSp.n-PSq.n.|=|.PSpq.n.| by VALUED_1:13,A43;
        |.PSpq.n.|<=absPSpq.n by Th13;
        then |.PSp.n-PSq.n.|<=(r2/(n+1))*(n+1) by A44,A42,XXREAL_0:2;
        then
A45:    |.PSp.n-PSq.n.|<=r2 by XCMPLX_1:87;
        0<=Sum(spn) by A25;
        then
A46:    |.Sum(spn).|=Sum(spn) by ABSVALUE:def 1;
        0<=Sum(sqn) by A25;
        then
A47:    |.Sum(sqn).|=Sum(sqn) by ABSVALUE:def 1;
        reconsider fRq=fR qua real-valued Function.q as Point of RealSpace by
METRIC_1:def 13,XREAL_0:def 1;
A48:    |.Sum(spn)-Sum(sqn).|<=|.Sum(spn).|+|.Sum(sqn).| by COMPLEX1:57;
A49:    fRp=Sum(sp) & fRq=Sum(sq) by A3;
        Sum(sp)=PSp.n+Sum(spn) & Sum(sq)=PSq.n+Sum(sqn) by A25,SERIES_1:15;
        then |.fR.p-fR.q.| =|.(PSp.n-PSq.n)+(Sum(spn)-Sum(sqn)).| by A49;
        then
A50:    |.fR.p-fR.q.|<=|.PSp.n-PSq.n.|+|.Sum(spn)-Sum(sqn).| by COMPLEX1:56;
        Sum(spn)<r4 & Sum(sqn)<r4 by A25;
        then |.Sum(spn).|+|.Sum(sqn).|<r4+r4 by A46,A47,XREAL_1:8;
        then |.Sum(spn)-Sum(sqn).|<r2 by A48,XXREAL_0:2;
        then |.PSp.n-PSq.n.|+|.Sum(spn)-Sum(sqn).|<r2+r2 by A45,XREAL_1:8;
        then |.fR.p-fR.q.|<rn by A50,XXREAL_0:2;
        then dist(fRp,fRq)<rn by TOPMETR:11;
        then fRq in Ball(fRp,rn) by METRIC_1:11;
        hence thesis by A5,A33;
      end;
      now
        let Fx be set;
        assume Fx in RNG;
        then consider x being object such that
A51:    x in dom FSn and
A52:    FSn.x=Fx by FUNCT_1:def 3;
        ex SS being Subset of T st SS = FSn.x & SS is open & p in SS & for
f1 st FS1.x=f1 for f1p be Point of RealSpace st f1p=f1.p holds f1 .:SS c= Ball(
        f1p,r2/(n+1)) by A16,A51;
        hence p in Fx by A52;
      end;
      then p in meet RNG by SETFAM_1:def 1;
      hence thesis by A19,A30,TOPS_2:20;
    end;
    hence fR is_continuous_at p by TMAP_1:43;
  end;
  then fR is continuous by TMAP_1:50;
  hence thesis by JORDAN5A:27;
end;
