reserve a,b,c,v,v1,x,y for object;
reserve V,A for set;
reserve d for TypeSCNominativeData of V,A;

theorem Th13:
  for d1 being NonatomicND of V,A
    for d2 being TypeSCNominativeData of V,A
   st v in V & v in dom d1 & not d1 in A & not naming(V,A,v,d2) in A
  holds dom local_overlapping(V,A,d1,d2,v) = dom d1
  proof
    let d1 be NonatomicND of V,A;
    let d2 be TypeSCNominativeData of V,A such that
A1: v in V and
A2: v in dom d1 and
A3: not d1 in A & not naming(V,A,v,d2) in A;
    set n = naming(V,A,v,d2);
A4: n = v .--> d2 by A1,NOMIN_1:def 13;
A5: dom(n) \/ dom(d1|(dom(d1)\dom(n))) = dom(d1)
    proof
A6:   dom(n) c= dom(d1) by A2,A4,ZFMISC_1:31;
      dom(d1|(dom(d1)\dom(n))) c= dom(d1) by RELAT_1:60;
      hence dom(n) \/ dom(d1|(dom(d1)\dom(n))) c= dom(d1) by A6,XBOOLE_1:8;
      let x be object;
      assume
A7:   x in dom(d1);
      per cases;
      suppose x = v;
        then x in dom(n) by A4,TARSKI:def 1;
        hence thesis by XBOOLE_0:def 3;
      end;
      suppose x <> v;
        then not x in dom(n) by A4,TARSKI:def 1;
        then x in dom(d1)\dom(n) by A7,XBOOLE_0:def 5;
        then x in dom(d1|(dom(d1)\dom(n))) by RELAT_1:57;
        hence thesis by XBOOLE_0:def 3;
      end;
    end;
    local_overlapping(V,A,d1,d2,v) = n \/ (d1|(dom(d1)\dom(n)))
    by A3,NOMIN_1:64;
    hence thesis by A5,XTUPLE_0:23;
  end;
