
theorem Th14:
  for I being non empty set for A being PLS-yielding ManySortedSet
of I for i being Element of I for S being Subset of A.i for L being Segre-like
non trivial-yielding ManySortedSubset of Carrier A holds product (L+*(i,S)) is
  Subset of Segre_Product A
proof
  let I be non empty set;
  let A be PLS-yielding ManySortedSet of I;
  let i be Element of I;
  let S be Subset of A.i;
  let L be Segre-like non trivial-yielding ManySortedSubset of Carrier A;
A1: dom (L+*(i,S)) = I by PARTFUN1:def 2
    .= dom Carrier A by PARTFUN1:def 2;
A2: now
    let a be object;
    assume a in dom (L+*(i,S));
    then
A3: a in I;
    then
A4: a in dom L by PARTFUN1:def 2;
    per cases;
    suppose
A5:   a=i;
      then (L+*(i,S)).a = S by A4,FUNCT_7:31;
      then (L+*(i,S)).a c= [#](A.i);
      hence (L+*(i,S)).a c= (Carrier A).a by A5,Th7;
    end;
    suppose
A6:   a<>i;
A7:   L c= Carrier A by PBOOLE:def 18;
      (L+*(i,S)).a = L.a by A6,FUNCT_7:32;
      hence (L+*(i,S)).a c= (Carrier A).a by A3,A7;
    end;
  end;
  Segre_Product A = TopStruct(#product Carrier A, Segre_Blocks A#) by
PENCIL_1:def 23;
  hence thesis by A1,A2,CARD_3:27;
end;
