reserve n,m,k,k1,k2 for Nat;
reserve X for non empty Subset of ExtREAL;
reserve Y for non empty Subset of REAL;
reserve seq for ExtREAL_sequence;
reserve e1,e2 for ExtReal;
reserve rseq for Real_Sequence;

theorem Th14:
  seq=rseq & rseq is convergent implies seq is
  convergent_to_finite_number & seq is convergent & lim seq = lim rseq
proof
  assume that
A1: seq = rseq and
A2: rseq is convergent;
    reconsider lrs = lim rseq as R_eal by XXREAL_0:def 1;
A3: now
    let e be Real;
    assume 0 < e;
    then consider n be Nat such that
A4: for m be Nat st n <= m holds |.rseq.m-lim rseq qua Complex.| < e
    by A2,SEQ_2:def 7;
    set N=n;
    now
      let m be Nat;
A5:   rseq.m - lim rseq = seq.m - lim rseq by A1,SUPINF_2:3;
      assume N <= m;
      then |.rseq.m-lim rseq qua Complex.| < e by A4;
      hence |. seq.m - lim rseq .| < e by A5,EXTREAL1:12;
    end;
    hence
    ex N be Nat st for m be Nat st N <= m
          holds |. seq.m - lrs .| < e;
  end;
  then
A6: seq is convergent_to_finite_number by MESFUNC5:def 8;
  then seq is convergent by MESFUNC5:def 11;
  hence thesis by A3,A6,MESFUNC5:def 12;
end;
