reserve R for Ring,
  I for Ideal of R,
  a, b for Element of R;
reserve R for add-associative right_zeroed right_complementable Abelian
    distributive left_unital non empty doubleLoopStr;
reserve I for Ideal of R;
reserve a,b for Element of R;
reserve x, y for Element of R/I;

theorem Th14:
  x = Class(EqRel(R,I),a) & y = Class(EqRel(R,I),b) implies
  x*y = Class(EqRel(R,I),a*b)
proof
  assume that
A1: x = Class(EqRel(R,I),a) and
A2: y = Class(EqRel(R,I),b);
  consider a1, b1 being Element of R such that
A3: x = Class(EqRel(R,I),a1) and
A4: y = Class(EqRel(R,I),b1) and
A5: (the multF of R/I).(x,y) = Class(EqRel(R,I),a1*b1) by Def6;
  b1-b in I by A2,A4,Th6;
  then
A6: a1*(b1-b) in I by IDEAL_1:def 2;
  (a1-a)*b = a1*b-a*b & a1*(b1-b) = a1*b1-a1*b by VECTSP_1:11,13;
  then
A7: a1*(b1-b)+(a1-a)*b = a1*b1-a1*b+a1*b-a*b by RLVECT_1:28
    .= a1*b1-(a*b) by Th1;
  a1-a in I by A1,A3,Th6;
  then (a1-a)*b in I by IDEAL_1:def 3;
  then (a1-a)*b+a1*(b1-b) in I by A6,IDEAL_1:def 1;
  hence thesis by A5,A7,Th6;
end;
