reserve L for Ortholattice,
  a, b, c for Element of L;

theorem Th14:
  for a, b being Element of B_6, x, y being Element of Benzene st
  a = x & b = y holds a "\/" b = x "\/" y & a "/\" b = x "/\" y
proof
  let a, b be Element of B_6, x, y be Element of Benzene;
  reconsider xy = x "\/" y as Element of B_6 by Th9,YELLOW_1:1;
  assume that
A1: a = x and
A2: b = y;
  x [= x "\/" y by LATTICES:5;
  then
A3: a <= xy by A1,Th13;
A4: for d being Element of B_6 st d >= a & d >= b holds xy <= d
  proof
    let d be Element of B_6;
    reconsider e = d as Element of Benzene by Th9,YELLOW_1:1;
    assume d >= a & d >= b;
    then x [= e & y [= e by A1,A2,Th13;
    then x "\/" y [= e by FILTER_0:6;
    hence thesis by Th13;
  end;
  y [= x "\/" y by LATTICES:5;
  then
A5: b <= xy by A2,Th13;
  reconsider xy = x "/\" y as Element of B_6 by Th9,YELLOW_1:1;
  x "/\" y [= y by LATTICES:6;
  then
A6: xy <= b by A2,Th13;
A7: for d being Element of B_6 st d <= a & d <= b holds xy >= d
  proof
    let d be Element of B_6;
    reconsider e = d as Element of Benzene by Th9,YELLOW_1:1;
    assume d <= a & d <= b;
    then e [= x & e [= y by A1,A2,Th13;
    then e [= x "/\" y by FILTER_0:7;
    hence thesis by Th13;
  end;
  x "/\" y [= x by LATTICES:6;
  then xy <= a by A1,Th13;
  hence thesis by A3,A5,A4,A6,A7,YELLOW_0:22,23;
end;
