 reserve L for non empty LattStr;
 reserve v64,v65,v66,v67,v103,v3,v102,v101,v100,v2,v1,v0 for Element of L;
 reserve L for distributive join-commutative meet-commutative
   non empty LattStr;
 reserve v0,v1,v2 for Element of L;
 reserve L for non empty LattStr;
 reserve v103,v3,v102,v101,v100,v2,v1,v0 for Element of L;

theorem AuxiliaryMcKenzie:
L is join-commutative join-associative meet-commutative meet-associative &
(for v1,v0 holds (v0"/\"(v0"\/"v1))=v0) &
(for v1,v0 holds (v0"\/"(v0"/\"v1))=v0)
implies
(for v1,v2,v0 holds (v0"\/"(v1"/\"(v0"/\"v2)))=v0) &
(for v1,v2,v0 holds (v0"/\"(v1"\/"(v0"\/"v2)))=v0) &
(for v2,v1,v0 holds (((v0"/\"v1)"\/"(v1"/\"v2))"\/"v1)=v1) &
(for v2,v1,v0 holds (((v0"\/"v1)"/\"(v1"\/"v2))"/\"v1)=v1)
proof
assume A2: L is join-commutative;
assume A3: L is join-associative;
assume A4: L is meet-commutative;
assume A5: L is meet-associative;
assume A6: for v1,v0 holds (v0"/\"(v0"\/"v1))=v0;
assume A7: for v1,v0 holds (v0"\/"(v0"/\"v1))=v0;
thus for v1,v2,v0 holds (v0"\/"(v1"/\"(v0"/\"v2)))=v0
proof
  let v1,v2,v0;
  (v0"\/"(v1"/\"(v0"/\"v2)))=(v0"\/"((v1"/\"v0)"/\"v2)) by A5
    .=(v0"\/"((v0"/\"v1)"/\"v2)) by A4
    .=(v0"\/"(v0"/\"(v1"/\"v2))) by A5
    .= v0 by A7;
  hence thesis;
end;

thus for v1,v2,v0 holds (v0"/\"(v1"\/"(v0"\/"v2)))=v0
proof
  let v1,v2,v0;
  (v0"/\"(v1"\/"(v0"\/"v2)))=(v0"/\"((v1"\/"v0)"\/"v2)) by A3
    .=(v0"/\"((v0"\/"v1)"\/"v2)) by A2
    .=(v0"/\"(v0"\/"(v1"\/"v2))) by A3
    .= v0 by A6;
  hence thesis;
end;

thus for v2,v1,v0 holds (((v0"/\"v1)"\/"(v1"/\"v2))"\/"v1)=v1
proof
let v2,v1,v0;
(((v0"/\"v1)"\/"(v1"/\"v2))"\/"v1)=(v0"/\"v1)"\/"((v1"/\"v2)"\/"v1) by A3
  .= (v0"/\"v1)"\/"(v1"\/"(v1"/\"v2)) by A2
  .= (v0"/\"v1)"\/"v1 by A7
  .= v1"\/"(v0"/\"v1) by A2
  .= v1"\/"(v1"/\"v0) by A4
  .= v1 by A7;
hence thesis;
end;

let v2,v1,v0;
(((v0"\/"v1)"/\"(v1"\/"v2))"/\"v1)=(v0"\/"v1)"/\"((v1"\/"v2)"/\"v1) by A5
  .= (v0"\/"v1)"/\"(v1"/\"(v1"\/"v2)) by A4
  .= (v0"\/"v1)"/\"v1 by A6
  .= v1"/\"(v0"\/"v1) by A4
  .= v1"/\"(v1"\/"v0) by A2
  .= v1 by A6;
hence thesis;
end;
