reserve i,j,k,l,m,n for Nat,
  D for non empty set,
  f for FinSequence of D;
reserve X for compact Subset of TOP-REAL 2;

theorem Th14:
  for f being FinSequence of TOP-REAL 2 st 1 <= i & i <= j & j <=
  len f holds L~mid(f,i,j) = union{ LSeg(f,k): i <= k & k < j}
proof
  let f be FinSequence of TOP-REAL 2;
  assume that
A1: 1 <= i and
A2: i <= j and
A3: j <= len f;
  set A = { LSeg(mid(f,i,j),m) : 1 <= m & m+1 <= len mid(f,i,j) }, B = { LSeg(
  f,l): i <= l & l < j};
  per cases by A2,XXREAL_0:1;
  suppose
A4: i = j;
A5: B = {}
    proof
      assume B <> {};
      then consider z being object such that
A6:   z in B by XBOOLE_0:def 1;
      ex l st z = LSeg(f,l) & i <= l & l < j by A6;
      hence contradiction by A4;
    end;
AA: i in dom f by FINSEQ_3:25,A1,A3,A4; then
    mid(f,i,j) = <*f.i*> by A4,FINSEQ_6:193
       .= <*f/.i*> by AA,PARTFUN1:def 6;
    hence thesis by A5,SPPOL_2:12,ZFMISC_1:2;
  end;
  suppose
A7: i < j;
    A = B
    proof
      hereby
        let x be object;
        assume x in A;
        then consider m such that
A8:     x = LSeg(mid(f,i,j),m) and
A9:     0+1 <= m and
A10:    m+1 <= len mid(f,i,j);
        i < m+i by A9,XREAL_1:29;
        then
A11:    i <= m+i-'1 by NAT_D:49;
        len mid(f,i,j) = j -' i + 1 by A1,A3,A7,FINSEQ_6:186;
        then
A12:    m < j -' i + 1 by A10,NAT_1:13;
        then m <= j -' i by NAT_1:13;
        then m <= j - i by A7,XREAL_1:233;
        then m+i >= m & m+i <= j by NAT_1:11,XREAL_1:19;
        then m+i-'1+1 <= j by A9,XREAL_1:235,XXREAL_0:2;
        then
A13:    m+i-'1 < j by NAT_1:13;
        x = LSeg(f,m+i-'1) by A1,A3,A7,A8,A9,A12,JORDAN4:19;
        hence x in B by A13,A11;
      end;
      let x be object;
      assume x in B;
      then consider l such that
A14:  x = LSeg(f,l) and
A15:  i <= l and
A16:  l < j;
      set m = l -' i + 1;
A17:  l - i < j - i by A16,XREAL_1:9;
      l -' i = l - i & j -' i = j - i by A15,A16,XREAL_1:233,XXREAL_0:2;
      then
A18:  m < j-'i+1 by A17,XREAL_1:6;
      len mid(f,i,j) = j -' i + 1 by A1,A3,A7,FINSEQ_6:186;
      then
A19:  m+1 <= len mid(f,i,j) by A18,NAT_1:13;
A20:  1 <= m by NAT_1:11;
      m+i-'1 = l -' i + i + 1 -' 1 .= l + 1 -' 1 by A15,XREAL_1:235
        .= l by NAT_D:34;
      then x = LSeg(mid(f,i,j),m) by A1,A3,A7,A14,A20,A18,JORDAN4:19;
      hence thesis by A20,A19;
    end;
    hence thesis;
  end;
end;
