
theorem  :: p. 100, Remark 1.4 (iv)
  for T being complete Scott TopLattice, S being upper Subset of T
  ex F being Subset-Family of T st S = meet F &
  for X being Subset of T st X in F holds X is a_neighborhood of S
proof
  let T be complete Scott TopLattice, S be upper Subset of T;
  defpred P[set] means $1 is a_neighborhood of S;
  set F = { X where X is Subset of T: P[X]};
  F is Subset-Family of T from DOMAIN_1:sch 7;
  then reconsider F as Subset-Family of T;
  take F;
  thus S = meet F
  proof
    [#]T is a_neighborhood of S by CONNSP_2:28;
    then
A1: [#]T in F;
    now
      let Z1 be set;
      assume Z1 in F;
      then ex X being Subset of T st Z1 = X & X is a_neighborhood of S;
      hence S c= Z1 by CONNSP_2:29;
    end;
    hence S c= meet F by A1,SETFAM_1:5;
    let x be object such that
A2: x in meet F and
A3: not x in S;
    reconsider p = x as Element of T by A2;
    (downarrow p)` is a_neighborhood of S by A3,Th13;
    then (downarrow p)` in F;
    then
A4: meet F c= (downarrow p)` by SETFAM_1:3;
    p <= p;
    then p in downarrow p by WAYBEL_0:17;
    hence contradiction by A2,A4,XBOOLE_0:def 5;
  end;
  let X be Subset of T;
  assume X in F;
  then ex Y being Subset of T st X = Y & Y is a_neighborhood of S;
  hence thesis;
end;
