reserve X for BCI-algebra;
reserve I for Ideal of X;
reserve a,x,y,z,u for Element of X;
reserve f,f9,g for sequence of  the carrier of X;
reserve j,i,k,n,m for Nat;

theorem
  ((0.X,(0.X,x)to_power m)to_power n)`=(0.X,x)to_power (m*n)
proof
  defpred P[set] means for j being Nat holds j=$1 & j<=n implies ((
  0.X,(0.X,x)to_power m)to_power j)`=(0.X,x)to_power (m*j);
  now
    let k;
    assume
A1: for j being Nat st j=k & j<=n holds ((0.X,(0.X,x)
    to_power m)to_power j)`=(0.X,x)to_power (m*j);
    let j be Nat;
    assume j=k+1 & j<=n;
    then
A2: k<=n by NAT_1:13;
    ((0.X,(0.X,x)to_power m)to_power (k+1))` =(((0.X,(0.X,x)to_power m)
    to_power k)\((0.X,x)to_power m))`by Th4
      .=((0.X,(0.X,x)to_power m)to_power k)`\((0.X,x)to_power m)` by BCIALG_1:9
      .=((0.X,x)to_power (m*k))\((0.X,x)to_power m)`by A1,A2
      .=(0.X,x)to_power (m*k+m)by Th13;
    hence ((0.X,(0.X,x)to_power m)to_power (k+1))` =(0.X,x)to_power (m*(k+1));
  end;
  then
A3: for k st P[k] holds P[k+1];
  ((0.X,(0.X,x)to_power m)to_power 0)` =(0.X)` by Th1
    .= 0.X by BCIALG_1:def 5;
  then
A4: P[0] by Th1;
  for n holds P[n] from NAT_1:sch 2(A4,A3);
  hence thesis;
end;
