reserve Omega for non empty set,
        Sigma for SigmaField of Omega,
        Prob for Probability of Sigma,
        A for SetSequence of Sigma,
        n,n1,n2 for Nat;

theorem Th15:
  @lim_inf Complement A = (@lim_sup A)` &
  Prob.(@lim_inf Complement A) + Prob.(@lim_sup A) = 1 &
  Prob.(lim_inf Complement A) + Prob.(lim_sup A) = 1
proof
A18: for A holds lim_inf A = @lim_inf A;
A23: @lim_inf Complement A = (@lim_sup A)`
proof
 reconsider CA = Complement A as SetSequence of Sigma;
 for x being object holds
   (x in @lim_inf Complement A iff x in (@lim_sup A)` )
      proof
       let x be object;
       hereby assume x in @lim_inf Complement A;
        then x in @lim_inf CA;
        then x in Omega & ex n being Nat st
              for k being Nat st k>=n holds not x in A.k by Th14;
        then x in Omega & not (x in @lim_sup A) by Th14;
        then x in Omega \ @lim_sup A by XBOOLE_0:def 5;
       hence x in (@lim_sup A)` by SUBSET_1:def 4;
       end;
       assume A24: x in (@lim_sup A)`;
        x in (Omega \ @lim_sup A) by A24,SUBSET_1:def 4;
        then not x in Intersection superior_setsequence A by XBOOLE_0:def 5;
        then ex m being Nat st
            for n being Nat st n>=m holds not x in A.n by Th14;
         then x in @lim_inf CA by A24,Th14;
       hence thesis;
      end;
  hence thesis by TARSKI:2;
end;
Prob.(@lim_inf Complement A) + Prob.(@lim_sup A) = 1
proof
 Prob.([#]Sigma \ @lim_sup A) + Prob.@lim_sup A = 1 by PROB_1:31;
 hence thesis by A23,SUBSET_1:def 4;
end;
hence thesis by A18,A23;
end;
