
theorem Th15:
  for X be non empty set, A be Subset-Family of X holds TopStruct
  (#X,UniCl FinMeetCl A#) is TopSpace-like
proof
  let X be non empty set, A be Subset-Family of X;
  set T = TopStruct (#X,UniCl FinMeetCl A#);
A1: [#]T in FinMeetCl A by Th8;
  now
    reconsider Y = {[#]T} as Subset-Family of X by ZFMISC_1:68;
    reconsider Y as Subset-Family of X;
    take Y;
    thus Y c= FinMeetCl A by A1,ZFMISC_1:31;
    thus [#]T = union Y by ZFMISC_1:25;
  end;
  hence the carrier of T in the topology of T by Def1;
  thus for a being Subset-Family of T st a c= the topology of T holds union a
  in the topology of T
  proof
    let a be Subset-Family of T such that
A2: a c= the topology of T;
    defpred P[set] means ex c being Subset of T st c in a & c = union $1;
    consider b being Subset-Family of FinMeetCl A such that
A3: for B being Subset of FinMeetCl A holds B in b iff P[B] from
    SUBSET_1:sch 3;
A4: a = { union B where B is Subset of FinMeetCl A: B in b }
    proof
      set gh = { union B where B is Subset of FinMeetCl A: B in b };
      hereby
        let x be object;
        assume
A5:     x in a;
        then reconsider x9 = x as Subset of X;
        consider V being Subset-Family of X such that
A6:     V c= FinMeetCl A and
A7:     x9 = union V by A2,A5,Def1;
        V in b by A3,A5,A6,A7;
        hence x in gh by A7;
      end;
      let x be object;
      assume x in gh;
      then consider B being Subset of FinMeetCl A such that
A8:   x = union B and
A9:   B in b;
      ex c being Subset of T st c in a & c = union B by A3,A9;
      hence thesis by A8;
    end;
    union union b = union { union B where B is Subset of FinMeetCl A: B
    in b } & union b c= bool X by EQREL_1:54,XBOOLE_1:1;
    hence thesis by A4,Def1;
  end;
  let a,b be Subset of T;
  assume a in the topology of T;
  then consider F being Subset-Family of X such that
A10: F c= FinMeetCl A and
A11: a = union F by Def1;
  assume b in the topology of T;
  then consider G being Subset-Family of X such that
A12: G c= FinMeetCl A and
A13: b = union G by Def1;
A14: union INTERSECTION(F,G) = a /\ b by A11,A13,SETFAM_1:28;
A15: INTERSECTION(F,G) c= FinMeetCl A by A10,A12,Th13;
  then INTERSECTION(F,G) is Subset-Family of X by XBOOLE_1:1;
  hence thesis by A15,A14,Def1;
end;
