reserve IIG for monotonic Circuit-like non void non empty ManySortedSign;
reserve SCS for non-empty Circuit of IIG;
reserve s for State of SCS;
reserve iv for InputValues of SCS;
reserve IIG for finite monotonic Circuit-like non void non empty
  ManySortedSign;
reserve SCS for non-empty Circuit of IIG;
reserve InpFs for InputFuncs of SCS;
reserve s for State of SCS;
reserve iv for InputValues of SCS;

theorem
  for n being Element of NAT st commute InpFs is constant &
InputVertices IIG is non empty & (Computation(s,InpFs)).n is stable
for m being Nat st n <= m
  holds (Computation(s,InpFs)).n = (Computation(s,InpFs)).m
proof
  let n be Element of NAT such that
A1: commute InpFs is constant and
A2: InputVertices IIG is non empty and
A3: (Computation(s,InpFs)).n is stable;
  defpred P[Nat] means n <= $1 implies (Computation(s,InpFs)).n = (
  Computation(s,InpFs)).$1;
A4: now
    let m be Nat;
    assume
A5: P[m];
    thus P[m+1]
    proof
A6:   IIG is with_input_V by A2;
      then reconsider iv = (commute InpFs).0 as InputValues of SCS by
CIRCUIT1:2;
      reconsider Ckm = (Computation(s,InpFs)).m as State of SCS;
A7:   dom commute InpFs = NAT by A2,PRE_CIRC:5;
      (m+1)-th_InputValues InpFs = (commute InpFs).(m+1) by A6,CIRCUIT1:def 2
        .= iv by A1,A7,FUNCT_1:def 10;
      then
A8:   (m+1)-th_InputValues InpFs c= (Computation(s,InpFs)).m by A1,A2,Th14;
      assume
A9:   n <= m+1;
      per cases by A9,NAT_1:8;
      suppose
        n <= m;
        hence (Computation(s,InpFs)).n = Following Ckm by A3,A5
          .= Following((Computation(s,InpFs)).m, (m+1)-th_InputValues InpFs)
        by A8,FUNCT_4:98
          .= (Computation(s,InpFs)).(m+1) by Def9;
      end;
      suppose
        n = m+1;
        hence thesis;
      end;
    end;
  end;
A10: P[ 0 ] by NAT_1:3;
  thus for m being Nat holds P[m] from NAT_1:sch 2(A10,A4);
end;
