reserve x, y, z for set,
  T for TopStruct,
  A for SubSpace of T,
  P, Q for Subset of T;
reserve TS for TopSpace;
reserve PS, QS for Subset of TS;
reserve S for non empty TopStruct;
reserve f for Function of T,S;

theorem Th15:
  f is continuous & rng f = [#] S & P is compact implies f.:P is compact
proof
  assume that
A1: f is continuous and
A2: rng f = [#] S and
A3: P is compact;
  let F be Subset-Family of S such that
A4: F is Cover of f.:P and
A5: F is open;
  reconsider G = ("f).:F as Subset-Family of T by TOPS_2:42;
  f.:P c= union F by A4,SETFAM_1:def 11;
  then
A6: f"(f.:P) c= f"(union F) by RELAT_1:143;
  P c= [#] T;
  then P c= dom f by FUNCT_2:def 1;
  then
A7: P c= f"(f.:P) by FUNCT_1:76;
  union G = f"(union F) by A2,FUNCT_3:26;
  then P c= union G by A6,A7;
  then
A8: G is Cover of P by SETFAM_1:def 11;
  G is open by A1,A5,TOPS_2:47;
  then consider G9 being Subset-Family of T such that
A9: G9 c= G and
A10: G9 is Cover of P and
A11: G9 is finite by A3,A8;
  reconsider F9= (.:f).:G9 as Subset-Family of S;
  take F9;
A12: (.:f).:((.:f)"F) c= F by FUNCT_1:75;
  (.:f).:(("f).:F) c= (.:f).:((.:f)"F) by FUNCT_3:29,RELAT_1:123;
  then
A13: (.:f).:G c= F by A12;
  (.:f).:G9 c= (.:f).:G by A9,RELAT_1:123;
  hence F9 c= F by A13;
A14: P c= union G9 by A10,SETFAM_1:def 11;
  dom f = [#] T by FUNCT_2:def 1;
  then union F9 = f.:(union G9) by FUNCT_3:14;
  then f.:P c= union F9 by A14,RELAT_1:123;
  hence F9 is Cover of f.:P by SETFAM_1:def 11;
  thus thesis by A11;
end;
