 reserve Rseq, Rseq1, Rseq2 for Function of [:NAT,NAT:],REAL;

theorem
  Partial_Sums Rseq is P-convergent implies
    Rseq is P-convergent & P-lim Rseq = 0
proof
   set CPS = Partial_Sums Rseq;
   assume A1: CPS is P-convergent;
   set Plim = P-lim CPS;
a2:for e be Real st 0 < e
    ex N be Nat st
     for n,m be Nat st n>=N & m>=N holds |. Rseq.(n,m) - 0 .| < e
   proof
    let e be Real;
    assume A3: 0 < e;
    set e1 = e/4;
    consider N be Nat such that
a4:  for n,m be Nat st n>=N & m>=N holds
      |. CPS.(n,m) - Plim .| < e1 by A1,A3,DBLSEQ_1:def 2;
    take N1 = N+1;
    hereby let n1,m1 be Nat;
     assume A5: n1>=N1 & m1>=N1; then
a5:  n1 > N & m1 > N by NAT_1:13; then
     reconsider n = n1-1, m=m1-1 as Element of NAT by NAT_1:20;
a6:  n1 = n+1 & m1=m+1;
     n+1 > N & m+1 > N by A5,NAT_1:13; then
a7:  n >= N & m >= N by NAT_1:13;
     Rseq.(n1,m1)
      = CPS.(n1,m1) - CPS.(n,m1) - CPS.(n1,m) + CPS.(n,m) by a6,thRS2
     .= ( (CPS.(n1,m1)- Plim) - (CPS.(n1,m)-Plim) )
       - ( (CPS.(n,m1)-Plim) - (CPS.(n,m)-Plim) ); then
a8:  |. Rseq.(n1,m1)-0 .|
      <= |. (CPS.(n1,m1)- Plim) - (CPS.(n1,m)-Plim) .|
      + |. (CPS.(n,m1)-Plim) - (CPS.(n,m)-Plim) .| by COMPLEX1:57;
a9:  |. (CPS.(n1,m1)- Plim) - (CPS.(n1,m)-Plim) .|
      <= |. CPS.(n1,m1)- Plim .| + |. CPS.(n1,m)-Plim .| by COMPLEX1:57;
a10: |. (CPS.(n,m1)-Plim) - (CPS.(n,m)-Plim) .|
      <= |. CPS.(n,m1)-Plim .| + |. CPS.(n,m)-Plim .| by COMPLEX1:57;
     |. CPS.(n1,m1) - Plim.| < e1 & |. CPS.(n,m1) - Plim.| < e1 &
     |. CPS.(n1,m) - Plim.| < e1 & |. CPS.(n,m)-Plim.| < e1 by a4,a5,a7; then
     |. CPS.(n1,m1) - Plim.| + |. CPS.(n1,m) - Plim.| < e1+e1 &
     |. CPS.(n,m1) - Plim.| + |. CPS.(n,m)-Plim.| < e1+e1 by XREAL_1:8; then
     |. (CPS.(n1,m1) - Plim) - (CPS.(n1,m) - Plim) .| < e1+e1 &
     |. (CPS.(n,m1) - Plim) - (CPS.(n,m) - Plim) .| < e1+e1
        by a9,a10,XXREAL_0:2; then
     |. (CPS.(n1,m1) - Plim) - (CPS.(n1,m) - Plim) .|
      + |. (CPS.(n,m1) - Plim) - (CPS.(n,m)-Plim) .| < (e1+e1)+(e1+e1)
             by XREAL_1:8;
     hence |. Rseq.(n1,m1) - 0 .| < e by a8,XXREAL_0:2;
    end;
   end;
   hence Rseq is P-convergent;
   hence P-lim Rseq = 0 by a2,DBLSEQ_1:def 2;
end;
