
theorem Lm83:
  for A be non empty closed_interval Subset of REAL,
      rho be Function of A,REAL,
      f be Point of
        DualSp (R_Normed_Algebra_of_ContinuousFunctions(ClstoCmp(A)))
    st
     rho is bounded_variation &
     ( for u be continuous PartFunc of REAL,REAL
         st dom u = A holds f.u = integral(u,rho) )
  holds ||. f .|| <= total_vd(rho)
proof
  let A be non empty closed_interval Subset of REAL,
      rho be Function of A,REAL,
      f be Point of
        DualSp (R_Normed_Algebra_of_ContinuousFunctions(ClstoCmp(A)));
  assume that
A1: rho is bounded_variation and
A2: for u be continuous PartFunc of REAL,REAL
        st dom u = A holds f.u = integral(u,rho);
  set X = R_Normed_Algebra_of_ContinuousFunctions(ClstoCmp(A));
A3: for u be continuous PartFunc of REAL,REAL
      st u in the carrier of X holds f.u = integral(u,rho)
  proof
    let u be continuous PartFunc of REAL,REAL;
    assume u in the carrier of X; then
    dom u = A & u is continuous PartFunc of REAL,REAL by Th80;
    hence f.u = integral(u,rho) by A2;
  end;
A4: for u be continuous PartFunc of REAL,REAL,
          v be Point of X
      st dom u = A & u=v holds
        |. integral(u,rho) .| <= ||.v.|| * total_vd(rho)
  proof
    let u be continuous PartFunc of REAL,REAL,
        v be Point of X;
    assume A5: dom u = A & u=v; then
B6: u is_RiemannStieltjes_integrable_with rho by A1,INTEGR23:21;
    consider T being DivSequence of A such that
A7:   delta(T) is convergent & lim delta(T) = 0 by INTEGRA4:11;
    set S = the middle_volume_Sequence of rho,u,T;
A9: |. middle_sum(S) .| is convergent by SEQ_4:13,B6,A7;
A10: for n be Nat holds
       |. (middle_sum(S)).n .| <= ||.v.|| * total_vd(rho)
    proof
      let n be Nat;
      set F = the var_volume of rho,T.n;
      reconsider v0 = ||.v.|| as Real;
      reconsider vF = v0*F as FinSequence of REAL;
      dom F = Seg len F by FINSEQ_1:def 3; then
B14:  dom vF = Seg len F by VALUED_1:def 5;
A15:  len(S.n) = len(T.n) by A1,A5,INTEGR22:def 5
              .= len F by INTEGR22:def 2
              .= len vF by B14,FINSEQ_1:def 3;
      for j be Nat st j in dom(S.n) holds |. (S.n).j .| <= (vF).j
      proof
        let j be Nat;
        assume j in dom(S.n); then
B17:    j in Seg len(S.n) by FINSEQ_1:def 3; then
        j in Seg len(T.n) by A1,A5,INTEGR22:def 5; then
A16:    j in dom(T.n) by FINSEQ_1:def 3;
        consider r be Real such that
A18:      r in rng (u|divset(T.n,j)) and
A19:      (S.n).j = r*(vol (divset(T.n,j),rho))
            by A1,A5,INTEGR22:def 5,A16;
A20:    |. (S.n).j .| = |.r.| * |. vol (divset(T.n,j),rho) .|
                          by COMPLEX1:65,A19
                     .= |.r.| * (F.j) by A16,INTEGR22:def 2;
        consider x be object such that
A21:      x in dom (u|divset(T.n,j)) & r = (u|divset(T.n,j)).x
            by A18,FUNCT_1:def 3;
        set AV = the carrier of ClstoCmp(A);
        u in BoundedFunctions(AV) by A5,Lm2; then
        consider u1 be Function of AV,REAL such that
A23:      u=u1 & u1| AV is bounded;
        x in A by A5,A21,RELAT_1:57; then
        reconsider x1=x as Element of AV by Lm1;
        reconsider v1=v as Point of
          R_Normed_Algebra_of_BoundedFunctions(AV) by Lm2;
        |. u1.x1 .| <= ||.v1.|| by A5,A23,C0SP1:26; then
        |. u.x .| <= ||.v.|| by A23,FUNCT_1:49; then
A24:    |.r.| <= ||.v.|| by A21,FUNCT_1:47;
        j in Seg len(T.n) by B17,A1,A5,INTEGR22:def 5; then
        j in Seg len F by INTEGR22:def 2; then
        j in dom F by FINSEQ_1:def 3; then
        0 <= F.j by INTEGR22:3; then
        |.r.| * (F.j) <= v0 * (F.j) by A24,XREAL_1:64;
        hence |. (S.n).j .| <= (vF).j by A20,VALUED_1:6;
      end; then
      |. Sum(S.n) .| <= Sum(vF) by A15,INTEGR23:3; then
A25:  |. Sum(S.n) .| <= ||.v.|| * Sum(F) by RVSUM_1:87;
      ||.v.|| * Sum(F) <= ||.v.|| * total_vd(rho)
        by A1,INTEGR22:5,XREAL_1:64; then
      |. Sum(S.n) .| <= ||.v.|| * total_vd(rho) by A25,XXREAL_0:2;
      hence thesis by INTEGR22:def 7;
    end;
    reconsider a = ||.v.|| * total_vd(rho) as Real;
    now
      let n be Nat;
      |. (middle_sum(S)).n .| <= a by A10; then
      |. (middle_sum(S)) .|.n <= a by SEQ_1:12;
      hence |. (middle_sum(S)) .|.n <= (seq_const a).n by SEQ_1:57;
    end; then
    lim |. middle_sum(S) .| <= lim (seq_const a) by A9,SEQ_2:18; then
A27: |. lim (middle_sum(S)) .| <= lim (seq_const a) by B6,A7,SEQ_4:14;
    lim (seq_const a) = (seq_const a).0 by SEQ_4:26
                     .= a by SEQ_1:57;
    hence thesis by B6,A1,A5,INTEGR22:def 9,A7,A27;
  end;
  reconsider g=f as Lipschitzian linear-Functional of X by DUALSP01:def 10;
  now
    let k be Real;
    assume k in PreNorms g;
    then
    consider u be Point of X such that
A28:  k = |. g.u .| & ||.u.|| <= 1;
    u in ContinuousFunctions(ClstoCmp(A)); then
    ex v be continuous RealMap of ClstoCmp(A) st u=v; then
    reconsider v=u as Function;
A29: dom v = A & v is continuous PartFunc of REAL,REAL by Th80;
    reconsider v as continuous PartFunc of REAL,REAL by Th80;
    |. integral(v,rho) .| <= ||.u.|| * total_vd(rho) by A4,A29; then
A30: |. g.u .| <= ||.u.|| * total_vd(rho) by A3;
    0 <= total_vd(rho) by A1,INTEGR22:6; then
    ||.u.|| * total_vd(rho) <= 1 * total_vd(rho) by A28,XREAL_1:64;
    hence k <= total_vd(rho) by A28,A30,XXREAL_0:2;
  end; then
  upper_bound PreNorms g <= total_vd(rho) by SEQ_4:45;
  hence ||. f .|| <= total_vd(rho) by DUALSP01:24;
end;
