reserve x for object;
reserve x0,r,r1,r2,g,g1,g2,p,y0 for Real;
reserve n,m,k,l for Element of NAT;
reserve a,b,d for Real_Sequence;
reserve h,h1,h2 for non-zero 0-convergent Real_Sequence;
reserve c,c1 for constant Real_Sequence;
reserve A for open Subset of REAL;
reserve f,f1,f2 for PartFunc of REAL,REAL;
reserve L for LinearFunc;
reserve R for RestFunc;

theorem Th15:
  f.x0 <> 0 & f is_differentiable_in x0 implies
  f^ is_differentiable_in x0 & diff(f^,x0) = - diff(f,x0)/(f.x0)^2
proof
  reconsider f1 = dom f --> jj as PartFunc of dom f, REAL by FUNCOP_1:45;
  reconsider f1 as PartFunc of REAL, REAL;
  assume that
A1: f.x0 <> 0 and
A2: f is_differentiable_in x0;
  consider N be Neighbourhood of x0 such that
A3: N c= dom f by A2;
A4: x0 in N by RCOMP_1:16;
A5: dom f1 = dom f by FUNCOP_1:13;
A6: rng f1 = {1}
  proof
    thus rng f1 c= {1} by FUNCOP_1:13;
    let x be object;
A7: x0 in N by RCOMP_1:16;
    assume x in {1};
    then x = 1 by TARSKI:def 1;
    then f1.x0 = x by A3,A7,FUNCOP_1:7;
    hence thesis by A5,A3,A7,FUNCT_1:def 3;
  end;
  then
A8: f1 is_differentiable_on N by A5,A3,FDIFF_1:11;
  then
A9: f1 is_differentiable_in x0 by A4,FDIFF_1:9;
  0 = (f1`|N).x0 by A5,A3,A6,FDIFF_1:11,RCOMP_1:16
    .= diff(f1,x0) by A8,A4,FDIFF_1:def 7;
  then
  diff(f1/f,x0) = (0 * f.x0 - diff(f,x0) * f1.x0)/((f.x0)^2) by A1,A2,A9,Th14;
  then
A10: diff(f1/f,x0) = (- diff(f,x0) * f1.x0)/((f.x0)^2)
    .= (- diff(f,x0) * 1)/((f.x0)^2) by A3,A4,FUNCOP_1:7
    .= - diff(f,x0)/((f.x0)^2) by XCMPLX_1:187;
A11: dom (f1/f) = dom f1 /\ (dom f \ f"{0}) by RFUNCT_1:def 1
    .= dom f \ f"{0} by A5,XBOOLE_1:28,36
    .= dom (f^) by RFUNCT_1:def 2;
A12: dom f \ f"{0} c= dom f1 by A5,XBOOLE_1:36;
A13: now
A14: dom f \ f"{0} = dom (f^) by RFUNCT_1:def 2;
    let r be Element of REAL such that
A15: r in dom (f1/f);
    thus (f1/f).r = f1.r * (f.r)" by A15,RFUNCT_1:def 1
      .= 1 * (f.r)" by A5,A12,A11,A15,A14,FUNCOP_1:7
      .= (f^).r by A11,A15,RFUNCT_1:def 2;
  end;
  f1/f is_differentiable_in x0 by A1,A2,A9,Th14;
  hence thesis by A10,A11,A13,PARTFUN1:5;
end;
