
theorem T4:
for n being Ordinal
for R being non degenerated Ring
for a,b being Element of R holds a|(n,R) *' (b|(n,R)) = (a * b)|(n,R)
proof
let n be Ordinal, L be non degenerated Ring; let a,b be Element of L;
set p = (a*b)|(n,L), q = (a|(n,L) *' (b|(n,L)));
set ap = a|(n,L), bp = b|(n,L);
A2: now let x be object;
    assume x in dom p;
    then reconsider i = x as Element of Bags n;
    consider s being FinSequence of the carrier of L such that
    A3: q.i = Sum s & len s = len decomp i &
        for k being Element of NAT st k in dom s
        ex b1,b2 being bag of n
        st (decomp i)/.k = <*b1,b2*> & s/.k = ap.b1*bp.b2 by POLYNOM1:def 10;
    per cases;
    suppose H0: i <> EmptyBag n;
      H1: for b1,b2 being bag of n
          st b1 <> EmptyBag n or b2 <> EmptyBag n holds ap.b1*bp.b2 = 0.L
          proof
          let b1,b2 be bag of n;
          assume b1 <> EmptyBag n or b2 <> EmptyBag n; then
          per cases;
          suppose b1 <> EmptyBag n;
            then ap.b1 = 0.L by POLYNOM7:18;
            hence thesis;
            end;
          suppose b2 <> EmptyBag n;
            then bp.b2 = 0.L by POLYNOM7:18;
            hence thesis;
            end;
          end;
      1 <= len(decomp i) by NAT_1:14;
      then 1 in Seg(len s) by A3;
      then H2: 1 in dom s by FINSEQ_1:def 3;
      H3: for k being Element of NAT st k in dom s holds s/.k = 0.L
          proof
          let k be Element of NAT;
          assume H4: k in dom s;
          then consider b1,b2 being bag of n such that
          H5: (decomp i)/.k = <*b1,b2*> & s/.k = ap.b1 * bp.b2 by A3;
          H8: dom s = Seg(len decomp i) by A3,FINSEQ_1:def 3
                   .= dom(decomp i) by FINSEQ_1:def 3;
          then H6: b1 = (divisors i)/.k by H4,H5,PRE_POLY:70;
          then (decomp i)/.k = <*b1,i-'b1*> by H4,H8,PRE_POLY:def 17;
          then H10: b2 = i -' b1 by H5,FINSEQ_1:77;
          dom divisors i = dom decomp i by PRE_POLY:def 17;
          then H7: k in Seg(len divisors i) by H4,H8,FINSEQ_1:def 3;
          then H11: 1 <= k & k <= len divisors i by FINSEQ_1:1;
          per cases;
          suppose k = 1;
            then b1 = EmptyBag n by H6,PRE_POLY:65;
            then b2 = i by H10,PRE_POLY:54;
            hence thesis by H0,H1,H5;
            end;
          suppose k <> 1; then
            H8: 1 < k by H11,XXREAL_0:1;
            per cases by XXREAL_0:1;
            suppose k = len divisors i;
              then b1 = i by H6,PRE_POLY:65;
              hence thesis by H0,H1,H5;
              end;
            suppose k < len divisors i;
              then b1 <> EmptyBag n by H8,H6,PRE_POLY:66;
              hence thesis by H5,H1;
              end;
            suppose k > len divisors i;
              hence thesis by H7,FINSEQ_1:1;
              end;
            end;
          end;
      then for k being Element of NAT st k in dom s & k <> 1 holds s/.k = 0.L;
      then Sum s = s/.1 by H2,POLYNOM2:3 .= ap.i * 0.L by H3,H2;
      hence q.x = p.x by H0,A3,POLYNOM7:18;
      end;
    suppose AS: i = EmptyBag n;
      then F: decomp i = <* <*EmptyBag n,EmptyBag n*> *> by PRE_POLY:73;
      then F1: len(decomp i) = 1 & (decomp i).1 = <*EmptyBag n,EmptyBag n*>
               by FINSEQ_1:40;
      dom(decomp i) = Seg 1 by F,FINSEQ_1:38;
      then F2: (decomp i)/.1 = <*EmptyBag n,EmptyBag n*>
                                       by F1,FINSEQ_1:3,PARTFUN1:def 6;
      H4: 1 = len s by F,A3,FINSEQ_1:40;
      then 1 in Seg(len s);
      then H3: 1 in dom s by FINSEQ_1:def 3;
      then consider b1,b2 being bag of n such that
      H2: (decomp i)/.1 = <*b1,b2*> & s/.1 = ap.b1 * bp.b2 by A3;
      s = <*s.1*> by H4,FINSEQ_1:40 .= <*s/.1*> by H3,PARTFUN1:def 6;
      then Sum s = ap.b1 * bp.b2 by H2,RLVECT_1:44
                .= ap.(EmptyBag n) * bp.b2 by F2,H2,FINSEQ_1:77
                .= ap.(EmptyBag n) * bp.(EmptyBag n) by F2,H2,FINSEQ_1:77
                .= a * bp.(EmptyBag n) by POLYNOM7:18
                .= a * b by POLYNOM7:18;
      hence q.x  = p.x by AS,A3,POLYNOM7:18;
      end;
    end;
dom p = Bags n by FUNCT_2:def 1;
hence thesis by A2;
end;
