reserve R for Ring, S for R-monomorphic Ring,
        K for Field, F for K-monomorphic Field,
        T for K-monomorphic comRing;

theorem Th13:
   for f being Monomorphism of K,F st K,F are_disjoint holds
   emb_iso f is onto
   proof
     let f be Monomorphism of K,F;
     assume
AS:  K,F are_disjoint;
     set g = emb_iso f;
E:   [#]embField f = carr f by defemb;
F:   dom g = [#]embField f by FUNCT_2:def 1;
A:   now let o be object;
     assume o in [#]F; then
     reconsider u = o as Element of F;
     per cases;
     suppose u in rng f; then
       consider y being object such that
B:     y in dom f & f.y = u by FUNCT_1:def 3;
     reconsider y as Element of K by B;
     reconsider yy = y as Element of embField f by E,XBOOLE_0:def 3;
       y in K; then g.yy = u by B,defiso;
       hence o in rng g by F,FUNCT_1:3;
     end;
     suppose not u in rng f; then
       u in ([#]F)\(rng f) by XBOOLE_0:def 5; then
     reconsider uu = u as Element of embField f by E,XBOOLE_0:def 3;
       not u in K by AS,XBOOLE_0:def 4; then
       g.uu = u by defiso;
       hence o in rng g by F,FUNCT_1:3;
     end;
   end;
   for o being object st o in rng g holds o in [#]F;
   hence g is onto by A,TARSKI:2;
  end;
