 reserve o for object;
 reserve F for non almost_trivial Field;
 reserve x,a for Element of F;
reserve n for non zero Nat;

theorem
   ex K being Field, p being Polynomial of K
   st deg p = n & p in [#]K /\ [#]Polynom-Ring K
   proof
     reconsider n as Element of NAT by ORDINAL1:def 12;
     set F = the non almost_trivial Field;
     set x = the non trivial Element of F;
     reconsider o = rpoly(n,0.F) as object;
     per cases;
       suppose not o in [#]F; then
       reconsider K = ExField(x,o) as Field by Th7,Th8,Th10,Th9,Th12,Th11;
       set p = rpoly(n,0.K);
       now let i be Element of NAT;
         per cases;
           suppose
A1:          i = 0;
             hence rpoly(n,0.F).i = -power(F).(0.F,n) by HURWITZ:25
             .= -0.F by Th6
             .= -0.K by Def8
             .= -power(K).(0.K,n) by Th6
             .= p.i by A1,HURWITZ:25;
           end;
           suppose
A2:          i = n;
             hence rpoly(n,0.F).i = 1_F by HURWITZ:25
             .= 1_K by Def8
             .= p.i by A2,HURWITZ:25;
           end;
           suppose
A3:          i <> 0 & i <> n;
             hence rpoly(n,0.F).i = 0.F by HURWITZ:26
             .= 0.K by Def8
             .= p.i by A3,HURWITZ:26;
           end;
         end; then
A4:     rpoly(n,0.F) = rpoly(n,0.K);
        take K;
        take p = rpoly(n,0.K);
A5:     p in [#]Polynom-Ring K by POLYNOM3:def 10;
        p in {rpoly(n,0.F)} by A4,TARSKI:def 1; then
        p in carr(x,rpoly(n,0.F)) by XBOOLE_0:def 3; then
        p in [#]K by Def8;
        hence thesis by A5,XBOOLE_0:def 4,HURWITZ:27;
      end;
      suppose
A6:     ex a being Element of F st a = rpoly(n,0.F);
        take F;
        take x = rpoly(n,0.F);
        x in [#]Polynom-Ring F by POLYNOM3:def 10;
        hence thesis by A6,HURWITZ:27,XBOOLE_0:def 4;
      end;
    end;
