reserve x,y for set;
reserve C,C9,D,D9,E for non empty set;
reserve c for Element of C;
reserve c9 for Element of C9;
reserve d,d1,d2,d3,d4,e for Element of D;
reserve d9 for Element of D9;
reserve i,j for natural Number;
reserve F for Function of [:D,D9:],E;
reserve p,q for FinSequence of D,
  p9,q9 for FinSequence of D9;
reserve f,f9 for Function of C,D,
  h for Function of D,E;
reserve T,T1,T2,T3 for Tuple of i,D;
reserve T9 for Tuple of i, D9;
reserve S for Tuple of j, D;
reserve S9 for Tuple of j, D9;

theorem
  F[:](p^q,d9) = (F[:](p,d9))^(F[:](q,d9))
proof
  defpred P[FinSequence of D] means F[:](p^($1),d9) = (F[:](p,d9))^(F[:]($1,d9
  ));
A1: for q,d st P[q] holds P[q^<*d*>]
  proof
    let q,d such that
A2: F[:](p^q,d9) = (F[:](p,d9))^(F[:](q,d9));
    thus F[:](p^(q^<*d*>),d9) = F[:]((p^q)^<*d*>,d9) by FINSEQ_1:32
      .= (F[:](p^q,d9))^<*F.(d,d9)*> by Th14
      .= (F[:](p,d9))^((F[:](q,d9))^<*F.(d,d9)*>) by A2,FINSEQ_1:32
      .= (F[:](p,d9))^(F[:](q^<*d*>,d9)) by Th14;
  end;
  F[:](p^(<*>D),d9) = F[:](p,d9) by FINSEQ_1:34
    .= (F[:](p,d9))^(<*>E) by FINSEQ_1:34
    .= (F[:](p,d9))^(F[:](<*>D,d9)) by FINSEQ_2:85;
  then
A3: P[<*>D];
  for q holds P[q] from FINSEQ_2:sch 2(A3,A1);
  hence thesis;
end;
