reserve E, x, y, X for set;
reserve A, B, C for Subset of E^omega;
reserve a, a1, a2, b for Element of E^omega;
reserve i, k, l, m, n for Nat;

theorem Th15:
  A |^.. n = {<%>E} iff A = {<%>E} or n = 0 & A = {}
proof
  thus A |^.. n = {<%>E} implies A = {<%>E} or n = 0 & A = {}
  proof
    assume that
A1: A |^.. n = {<%>E} and
A2: A <> {<%>E} and
A3: n <> 0 or A <> {};
    per cases by A3;
    suppose
A4:   n <> 0;
      <%>E in A |^.. n by A1,ZFMISC_1:31;
      then consider k such that
A5:   n <= k and
A6:   <%>E in A |^ k by Th2;
      k > 0 by A4,A5;
      then
A7:   <%>E in A by A6,FLANG_1:31;
      not ex x being object st x in A & x <> <%>E by A1,Th14;
      hence contradiction by A2,A7,ZFMISC_1:35;
    end;
    suppose
      A <> {};
      then ex x being object st x in A & x <> <%>E by A2,ZFMISC_1:35;
      hence contradiction by A1,Th14;
    end;
  end;
  assume
A8: A = {<%>E} or n = 0 & A = {};
  per cases by A8;
  suppose
A9: A = {<%>E};
A10: now
      let x be object;
      assume x in {<%>E};
      then x in A |^ n by A9,FLANG_1:28;
      hence x in A |^.. n by Th2;
    end;
    now
      let x be object;
      assume x in A |^.. n;
      then ex k st n <= k & x in A |^ k by Th2;
      hence x in {<%>E} by A9,FLANG_1:28;
    end;
    hence thesis by A10,TARSKI:2;
  end;
  suppose
A11: n = 0 & A = {};
    hence A |^.. n = A* by Th11
      .= {<%>E} by A11,FLANG_1:47;
  end;
end;
