reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th15:
  Int h_strip(G,0) = { |[r,s]| : s < G*(1,1)`2 }
proof
  0 <> len G by MATRIX_0:def 10;
  then 1 <= len G by NAT_1:14;
  then
A1: h_strip(G,0) = { |[r,s]| : s <= G*(1,1)`2 } by GOBOARD5:7;
  thus Int h_strip(G,0) c= { |[r,s]| : s < G*(1,1)`2 }
  proof
    let x be object;
    assume
A2: x in Int h_strip(G,0);
    then reconsider u = x as Point of Euclid 2 by Lm6;
    consider s1 being Real such that
A3: s1 > 0 and
A4: Ball(u,s1) c= h_strip(G,0) by A2,Th5;
    reconsider p = u as Point of TOP-REAL 2 by Lm6;
A5: p = |[p`1,p`2]| by EUCLID:53;
    set q = |[p`1+0,p`2+s1/2]|;
    s1/2 < s1 by A3,XREAL_1:216;
    then q in Ball(u,s1) by A3,A5,Th8;
    then q in h_strip(G,0) by A4;
    then ex r2,s2 st q = |[r2,s2]| & s2 <= G*(1,1)`2 by A1;
    then
A6: p`2+s1/2 <= G*(1,1)`2 by SPPOL_2:1;
    p`2 < p`2 + s1/2 by A3,XREAL_1:29,215;
    then p`2 < G*(1,1)`2 by A6,XXREAL_0:2;
    hence thesis by A5;
  end;
  let x be object;
  assume x in { |[r,s]| : s < G*(1,1)`2 };
  then consider r,s such that
A7: x = |[r,s]| and
A8: s < G*(1,1)`2;
  reconsider u = |[r,s]| as Point of Euclid 2 by TOPREAL3:8;
A9: Ball(u,G*(1,1)`2-s) c= h_strip(G,0)
  proof
    let y be object;
A10: Ball(u,G*(1,1)`2-s) = { v : dist(u,v)<G*(1,1)`2-s} by METRIC_1:17;
    assume y in Ball(u,G*(1,1)`2-s);
    then consider v such that
A11: v = y and
A12: dist(u,v)<G*(1,1)`2-s by A10;
    reconsider q = v as Point of TOP-REAL 2 by TOPREAL3:8;
    (s - q`2)^2 >= 0 & (s - q`2)^2 + 0 <= (r - q`1)^2 + (s - q`2)^2 by
XREAL_1:6,63;
    then
A13: sqrt (s - q`2)^2 <= sqrt ((r - q`1)^2 + (s - q`2)^2) by SQUARE_1:26;
A14: q = |[q`1,q`2]| by EUCLID:53;
    then sqrt ((r - q`1)^2 + (s - q`2)^2) < G*(1,1)`2-s by A12,Th6;
    then sqrt (s - q`2)^2 <= G*(1,1)`2-s by A13,XXREAL_0:2;
    then
A15: |.s-q`2.| <= G*(1,1)`2-s by COMPLEX1:72;
    per cases;
    suppose
      s <= q`2;
      then
A16:  q`2-s >= 0 by XREAL_1:48;
      |.s-q`2.| = |.-(s-q`2).| by COMPLEX1:52
        .= q`2 - s by A16,ABSVALUE:def 1;
      then q`2 <= G*(1,1)`2 by A15,XREAL_1:9;
      hence thesis by A1,A11,A14;
    end;
    suppose
      s >= q`2;
      then q`2 <= G*(1,1)`2 by A8,XXREAL_0:2;
      hence thesis by A1,A11,A14;
    end;
  end;
  reconsider B = Ball(u,G*(1,1)`2-s) as Subset of TOP-REAL2 by TOPREAL3:8;
A17: B is open by Th3;
  u in Ball(u,G*(1,1)`2-s) by A8,Th1,XREAL_1:50;
  hence thesis by A7,A9,A17,TOPS_1:22;
end;
