reserve a,b,c,d,e,x,r for Real,
  A for non empty closed_interval Subset of REAL,
  f,g for PartFunc of REAL,REAL;

theorem Th15:
  for n be Nat st n > 0 & vol A > 0 holds ex D being
  Division of A st len D = n & for i be Nat st i in dom D holds D.i=
  lower_bound A + vol(A)/n*i
proof
  let n be Nat;
  assume that
A1: n > 0 and
A2: vol A > 0;
  deffunc F(Nat)=In(lower_bound A + vol(A)/n*$1,REAL);
  consider D being FinSequence of REAL such that
A3: len D = n & for i be Nat st i in dom D holds D.i=F(i) from FINSEQ_2:
  sch 1;
A4: for i,j be Nat st i in dom D & j in dom D & i<j holds D.i < D
  .j
  proof
    let i,j be Nat;
    assume that
A5: i in dom D and
A6: j in dom D and
A7: i < j;
    vol(A)/n > 0 by A1,A2,XREAL_1:139;
    then vol(A)/n*i < vol(A)/n*j by A7,XREAL_1:68;
    then F(i) < F(j) by XREAL_1:6;
    then D.i < F(j) by A3,A5;
    hence thesis by A3,A6;
  end;
A8: dom D = Seg n by A3,FINSEQ_1:def 3;
  reconsider D as non empty increasing FinSequence of REAL by A1,A3,A4,
SEQM_3:def 1;
  D.(len D)=F(n) by A3,A8,FINSEQ_1:3;
  then
A9: D.(len D)=lower_bound A + vol(A) by A1,XCMPLX_1:87;
  for x1 being object st x1 in rng D holds x1 in A
  proof
    let x1 be object;
    assume x1 in rng D;
    then consider i be Element of NAT such that
A10: i in dom D and
A11: D.i=x1 by PARTFUN1:3;
A12: 1 <= i by A10,FINSEQ_3:25;
    i <= len D by A10,FINSEQ_3:25;
    then vol(A)/n*i <= vol(A)/n*n by A2,A3,XREAL_1:64;
    then vol(A)/n*i <= vol A by A1,XCMPLX_1:87;
    then
A13: lower_bound A + vol(A)/n*i <= lower_bound A+ vol A by XREAL_1:6;
    vol(A)/n>0 by A1,A2,XREAL_1:139;
    then
A14: lower_bound A <= lower_bound A + vol(A)/n*i by A12,XREAL_1:29,129;
    x1 = F(i) by A3,A10,A11;
    hence thesis by A14,A13,INTEGRA2:1;
  end;
  then rng D c= A;
  then reconsider D as Division of A by A9,INTEGRA1:def 2;
  take D;
  thus len D = n by A3;
  let i be Nat;
  assume i in dom D;
  then D.i = F(i) by A3;
  hence thesis;
end;
