reserve i,j,k,n for Nat,
  X,Y,a,b,c,x for set,
  r,s for Real;
reserve f,g for FinSequence of TOP-REAL 2;
reserve f for non constant standard special_circular_sequence,
  p,p1,p2,q for Point of TOP-REAL 2;

theorem Th15:
  a in (L~f)` & b in (L~f)` & (not ex C be Subset of TOP-REAL 2 st
  (C is_a_component_of (L~f)` & a in C & b in C)) iff ( a in LeftComp f & b in
  RightComp f or a in RightComp f & b in LeftComp f )
proof
A1: LeftComp f is_a_component_of (L~f)` by GOBOARD9:def 1;
A2: RightComp f is_a_component_of (L~f)` by GOBOARD9:def 2;
  thus a in (L~f)` & b in (L~f)` & (not ex C be Subset of TOP-REAL 2 st (C
  is_a_component_of (L~f)` & a in C & b in C)) implies ( a in LeftComp f & b in
  RightComp f or a in RightComp f & b in LeftComp f )
  proof
    assume that
A3: a in (L~f)` and
A4: b in (L~f)` and
A5: not ex C be Subset of TOP-REAL 2 st (C is_a_component_of (L~f)` &
    a in C & b in C);
A6: a in LeftComp f \/ RightComp f by A3,GOBRD12:10;
A7: b in LeftComp f \/ RightComp f by A4,GOBRD12:10;
    per cases by A6,XBOOLE_0:def 3;
    suppose
A8:   a in LeftComp f;
      now
        per cases by A7,XBOOLE_0:def 3;
        suppose
          b in LeftComp f;
          hence thesis by A1,A5,A8;
        end;
        suppose
          b in RightComp f;
          hence thesis by A8;
        end;
      end;
      hence thesis;
    end;
    suppose
A9:   a in RightComp f;
      now
        per cases by A7,XBOOLE_0:def 3;
        suppose
          b in RightComp f;
          hence thesis by A2,A5,A9;
        end;
        suppose
          b in LeftComp f;
          hence thesis by A9;
        end;
      end;
      hence thesis;
    end;
  end;
  thus ( a in LeftComp f & b in RightComp f or a in RightComp f & b in
LeftComp f ) implies a in (L~f)` & b in (L~f)` & not ex C be Subset of TOP-REAL
  2 st (C is_a_component_of (L~f)` & a in C & b in C)
  proof
    assume
A10: a in LeftComp f & b in RightComp f or a in RightComp f & b in LeftComp f;
    thus a in (L~f)` & b in (L~f)`
    proof
      LeftComp f c= LeftComp f \/ RightComp f by XBOOLE_1:7;
      then
A11:  LeftComp f c= (L~f)` by GOBRD12:10;
      RightComp f c= LeftComp f \/ RightComp f by XBOOLE_1:7;
      then
A12:  RightComp f c= (L~f)` by GOBRD12:10;
      per cases by A10;
      suppose
        a in LeftComp f & b in RightComp f;
        hence thesis by A11,A12;
      end;
      suppose
        a in RightComp f & b in LeftComp f;
        hence thesis by A11,A12;
      end;
    end;
    now
      given C be Subset of TOP-REAL 2 such that
A13:  C is_a_component_of (L~f)` and
A14:  a in C and
A15:  b in C;
      now
        per cases by A10;
        suppose
A16:      a in LeftComp f & b in RightComp f;
          now
            per cases by A1,A13,GOBOARD9:1;
            suppose
              C = LeftComp f;
              then not LeftComp f misses RightComp f by A15,A16,XBOOLE_0:3;
              hence contradiction by GOBRD14:14;
            end;
            suppose
              C misses LeftComp f;
              hence contradiction by A14,A16,XBOOLE_0:3;
            end;
          end;
          hence contradiction;
        end;
        suppose
A17:      a in RightComp f & b in LeftComp f;
          now
            per cases by A1,A13,GOBOARD9:1;
            suppose
              C = LeftComp f;
              then not LeftComp f misses RightComp f by A14,A17,XBOOLE_0:3;
              hence contradiction by GOBRD14:14;
            end;
            suppose
              C misses LeftComp f;
              hence contradiction by A15,A17,XBOOLE_0:3;
            end;
          end;
          hence contradiction;
        end;
      end;
      hence contradiction;
    end;
    hence not ex C be Subset of TOP-REAL 2 st (C is_a_component_of (L~f)` & a
    in C & b in C);
  end;
end;
