reserve p1, p2 for Point of TOP-REAL 2,
  C for Simple_closed_curve,
  P for Subset of TOP-REAL 2;

theorem Th15:
  for T1,T2 being non empty TopSpace, f being Function of T1,T2 st
  f is being_homeomorphism for A,B being Subset of T1 st A is_a_component_of B
  holds f.:A is_a_component_of f.:B
proof
  let T1,T2 be non empty TopSpace, f be Function of T1,T2 such that
A1: f is being_homeomorphism;
  let A,B be Subset of T1;
  given A1 being Subset of T1|B such that
A2: A1 = A and
A3: A1 is a_component;
A4: [#](T2|(f.:B)) = f.:B by PRE_TOPC:def 5;
A5: dom f = the carrier of T1 by FUNCT_2:def 1;
A6: [#](T1|B) = B by PRE_TOPC:def 5;
  then reconsider A2 = f.:A as Subset of T2|(f.:B) by A2,A4,RELAT_1:123;
  per cases;
  suppose
A7: B is empty;
    then f.:B = {};
    then
A8: A2 = {} by A4,XBOOLE_1:3;
    {} T2 = f.:B by A7;
    hence thesis by A8,JORDAN1K:6;
  end;
  suppose
    B is non empty;
    then reconsider S1 = T1|B, S2 = T2|(f.:B) as non empty TopSpace by A5;
    take A2;
    thus A2 = f.:A;
    reconsider fB = f|B as Function of S1,S2 by Th12;
    fB.:A = A2 by A2,A6,RELAT_1:129;
    hence thesis by A1,A2,A3,Th11,Th14;
  end;
end;
