reserve x,x1,x2,y,z,z1 for set;
reserve s1,r,r1,r2 for Real;
reserve s,w1,w2 for Real;
reserve n,i for Element of NAT;
reserve X for non empty TopSpace;
reserve p,p1,p2,p3 for Point of TOP-REAL n;
reserve P for Subset of TOP-REAL n;

theorem Th15:
  for a,b being Real,f being Function of TOP-REAL n,R^1,i
st (for p being Element of TOP-REAL n holds f.p=p/.i) holds f"({s:a<s & s<
  b})={p where p is Element of TOP-REAL n: a<p/.i & p/.i<b}
proof
  let a,b be Real, f be Function of TOP-REAL n,R^1,i;
  assume
A1: for p being Element of TOP-REAL n holds f.p=p/.i;
  thus f"({s:a<s & s<b})={p where p is Element of TOP-REAL n: a<p/.i & p/.i<b}
  proof
A2: f"({s:a<s & s<b}) c= {p where p is Element of TOP-REAL n: a<p/.i & p/.i<b}
    proof
      let x be object;
      assume
A3:   x in f"({s:a<s & s<b});
      then reconsider px=x as Element of (TOP-REAL n);
      f.x in {s:a<s & s<b} by A3,FUNCT_1:def 7;
      then
A4:   ex s st s=f.x & a<s & s<b;
      f.px=px/.i by A1;
      hence thesis by A4;
    end;
A5: dom f =the carrier of (TOP-REAL n) by FUNCT_2:def 1;
    {p where p is Element of TOP-REAL n: a<p/.i & p/.i<b} c= f"( {s:a<s & s<b})
    proof
      let x be object;
      assume x in {p where p is Element of TOP-REAL n: a<p/.i & p/.i<b};
      then consider p being Element of TOP-REAL n such that
A6:   x=p and
A7:   a<p/.i & p/.i<b;
      f.x=p/.i by A1,A6;
      then f.x in {s:a<s & s<b} by A7;
      hence thesis by A5,A6,FUNCT_1:def 7;
    end;
    hence thesis by A2,XBOOLE_0:def 10;
  end;
end;
