reserve i,j,k,n for Nat,
  D for non empty set,
  f, g for FinSequence of D;
reserve G for Go-board,
  f, g for FinSequence of TOP-REAL 2,
  p for Point of TOP-REAL 2,
  r, s for Real,
  x for set;

theorem Th15:
  f is_sequence_on G & f is special implies
 for k being Nat st 1 <= k & k+1 <= len f
  holds Int left_cell(f,k,G) misses L~f & Int right_cell(f,k,G) misses L~f
proof
  assume that
A1: f is_sequence_on G and
A2: f is special;
  let k be Nat such that
A3: 1 <= k & k+1 <= len f;
  consider i1,j1,i2,j2 being Nat such that
A4: [i1,j1] in Indices G and
A5: f/.k = G*(i1,j1) and
A6: [i2,j2] in Indices G and
A7: f/.(k+1) = G*(i2,j2) and
A8: i1 = i2 & j1+1 = j2 or i1+1 = i2 & j1 = j2 or i1 = i2+1 & j1 = j2 or
  i1 = i2 & j1 = j2+1 by A1,A3,JORDAN8:3;
A9: i2 <= len G by A6,MATRIX_0:32;
A10: i1 <= len G by A4,MATRIX_0:32;
  then
A11: i1-'1 <= len G by NAT_D:44;
A12: j2 <= width G by A6,MATRIX_0:32;
  then
A13: j2-'1 <= width G by NAT_D:44;
A14: j1+1 > j1 & j2+1 > j2 by NAT_1:13;
A15: j1 <= width G by A4,MATRIX_0:32;
  then
A16: j1-'1 <= width G by NAT_D:44;
A17: i1+1 > i1 & i2+1 > i2 by NAT_1:13;
  per cases by A8;
  suppose
    i1 = i2 & j1+1 = j2;
    then right_cell(f,k,G) = cell(G,i1,j1) & left_cell(f,k,G) = cell(G,i1-'1,
    j1) by A1,A3,A4,A5,A6,A7,A14,GOBRD13:def 2,def 3;
    hence thesis by A1,A2,A10,A15,A11,Th14;
  end;
  suppose
    i1+1 = i2 & j1 = j2;
    then right_cell(f,k,G) = cell(G,i1,j1-'1) & left_cell(f,k,G) = cell(G,i1,
    j1) by A1,A3,A4,A5,A6,A7,A17,GOBRD13:def 2,def 3;
    hence thesis by A1,A2,A10,A15,A16,Th14;
  end;
  suppose
    i1 = i2+1 & j1 = j2;
    then
    right_cell(f,k,G) = cell(G,i2,j2) & left_cell(f,k,G) = cell(G,i2,j2-'
    1) by A1,A3,A4,A5,A6,A7,A17,GOBRD13:def 2,def 3;
    hence thesis by A1,A2,A9,A12,A13,Th14;
  end;
  suppose
    i1 = i2 & j1 = j2+1;
    then right_cell(f,k,G) = cell(G,i1-'1,j2) & left_cell(f,k,G) = cell(G,i1,
    j2) by A1,A3,A4,A5,A6,A7,A14,GOBRD13:def 2,def 3;
    hence thesis by A1,A2,A10,A12,A11,Th14;
  end;
end;
