
theorem HelpMaxPrime:
  for L be Lattice,
      F be Filter of L,
      a be Element of L,
      G be set st
    G = { x where x is Element of L : ex u being Element of L st
      u in F & a "/\" u [= x } & a in G holds
    G is Filter of L
  proof
    let L be Lattice;
    let F be Filter of L;
    let a be Element of L;
    let G be set;
    assume
A1: G = { x where x is Element of L : ex u being Element of L st
      u in F & a "/\" u [= x } & a in G;
    G c= the carrier of L
    proof
      let y be object;
      assume y in G; then
      consider x being Element of L such that
S2:   y = x & ex u being Element of L st u in F & a "/\" u [= x by A1;
      thus thesis by S2;
    end; then
    reconsider G1 = G as Subset of L;
    set u = the Element of F;
ZD: G1 is meet-closed
    proof
      let p,q be Element of L;
      assume
P0:   p in G1 & q in G1; then
      consider xx being Element of L such that
P1:   xx = p & ex u being Element of L st u in F & a "/\" u [= xx by A1;
      consider u1 being Element of L such that
P3:   u1 in F & a "/\" u1 [= p by P1;
      consider yy being Element of L such that
P2:   yy = q & ex u being Element of L st u in F & a "/\" u [= yy
        by P0,A1;
      consider u2 being Element of L such that
P4:   u2 in F & a "/\" u2 [= q by P2;
P6:   (a "/\" u1) "/\" (a "/\" u2) [= p "/\" q by P3,P4,FILTER_0:5;
P7:   u1 "/\" u2 in F by P3,P4,FILTER_0:8;
      (a "/\" u1) "/\" (a "/\" u2) = a "/\" u1 "/\" a "/\" u2
        by LATTICES:def 7
        .= (a "/\" a) "/\" u1 "/\" u2 by LATTICES:def 7
        .= a "/\" (u1 "/\" u2) by LATTICES:def 7;
      hence thesis by P7,P6,A1;
    end;
    G1 is final
    proof
      let p, q be Element of L;
      assume
Y0:   p [= q & p in G1; then
      consider s being Element of L such that
Y1:   s = p & ex u being Element of L st
      u in F & a "/\" u [= s by A1;
      consider u being Element of L such that
Y2:   u in F & a "/\" u [= s by Y1;
      a "/\" u [= q by Y2,Y0,Y1,LATTICES:7;
      hence thesis by Y2,A1;
    end;
    hence thesis by A1,ZD;
end;
