 reserve X,Y,Z,E,F,G,S,T for RealLinearSpace;
 reserve X,Y,Z,E,F,G for RealNormSpace;
 reserve S,T for RealNormSpace-Sequence;

theorem IS04A:
  ex I be LinearOperator of
    R_NormSpace_of_BoundedLinearOperators
      (X,R_NormSpace_of_BoundedLinearOperators(Y,Z)),
    R_NormSpace_of_BoundedMultilinearOperators(<*X,Y*>,Z)
  st I is bijective isometric
   & for u be Point of R_NormSpace_of_BoundedLinearOperators
       (X,R_NormSpace_of_BoundedLinearOperators(Y,Z))
     holds ||.u.|| = ||. I.u .||
   & for x be Point of X,y be Point of Y holds (I.u).<*x,y*> = (u.x).y
  proof
    consider I be LinearOperator of
      R_NormSpace_of_BoundedLinearOperators
        (X,R_NormSpace_of_BoundedLinearOperators(Y,Z)),
      R_NormSpace_of_BoundedBilinearOperators(X,Y,Z) such that
    A1: I is bijective
      & for u be Point of R_NormSpace_of_BoundedLinearOperators
        (X,R_NormSpace_of_BoundedLinearOperators(Y,Z))
        holds ||.u.|| = ||. I.u .||
      & for x be Point of X,y be Point of Y holds
        (I.u).(x,y) = (u.x).y by LOPBAN_9:27;
    consider J be LinearOperator of
      R_NormSpace_of_BoundedBilinearOperators(X,Y,Z),
      R_NormSpace_of_BoundedMultilinearOperators(<*X,Y*>,Z) such that
    A2: J is bijective isometric
      & for u be Point of R_NormSpace_of_BoundedBilinearOperators(X,Y,Z)
        holds J.u = u * (IsoCPNrSP(X,Y))" by IS03A;
    reconsider K = J*I as LinearOperator of
      R_NormSpace_of_BoundedLinearOperators
        (X,R_NormSpace_of_BoundedLinearOperators(Y,Z)),
      R_NormSpace_of_BoundedMultilinearOperators(<*X,Y*>,Z) by LOPBAN_2:1;
    take K;
    thus K is bijective by A1,A2,FUNCT_2:27;
    A3: for x being Element of R_NormSpace_of_BoundedLinearOperators
          (X,R_NormSpace_of_BoundedLinearOperators(Y,Z))
        holds ||.K. x.|| = ||.x.||
    proof
      let x be Element of R_NormSpace_of_BoundedLinearOperators
        (X,R_NormSpace_of_BoundedLinearOperators(Y,Z));
      thus ||. K.x .|| = ||. J.(I.x) .|| by FUNCT_2:15
        .= ||. I.x .|| by A2,NDIFF_7:7
        .= ||.x.|| by A1;
    end;
    hence K is isometric by NDIFF_7:7;
    let u be Point of R_NormSpace_of_BoundedLinearOperators
        (X,R_NormSpace_of_BoundedLinearOperators(Y,Z));
    thus ||.K.u.|| = ||.u.|| by A3;
    let x be Point of X,y be Point of Y;
A4: K.u = J.(I.u) by FUNCT_2:15;
    reconsider xy = <*x,y*> as Point of product <*X,Y*> by PRVECT_3:19;
    thus (K.u).<*x,y*> = ((I.u) * (IsoCPNrSP (X,Y))").xy by A2,A4
    .= (I.u).((IsoCPNrSP(X,Y))" .xy) by FUNCT_2:15
    .= (I.u).(x,y) by NDIFF_7:18
    .= (u.x).y by A1;
  end;
