
theorem
for f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
 g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
 x,y be Element of REAL
st f is_uniformly_continuous_on dom f & f = g holds
  ProjPMap1(g,[x,y]) is uniformly_continuous
proof
    let f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
    g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
    x,y be Element of REAL;
    assume that
A1: f is_uniformly_continuous_on dom f and
A2: f = g;

    for r be Real st 0 < r ex s be Real st 0 < s &
     for z1,z2 be Real st z1 in dom ProjPMap1(g,[x,y])
       & z2 in dom ProjPMap1(g,[x,y]) & |. z1-z2 .| < s
      holds |. ProjPMap1(g,[x,y]).z1 - ProjPMap1(g,[x,y]).z2 .| < r
    proof
     let r be Real;
     assume 0 < r; then
     consider s be Real such that
A3:  0 < s and
A4:  for p1,p2 be Point of [:[:RNS_Real,RNS_Real:],RNS_Real:]
      st p1 in dom f & p2 in dom f & ||. p1-p2 .|| < s
       holds ||. f/.p1 - f/.p2 .|| < r by A1;

     now let z1,z2 be Real;
      assume that
A5:   z1 in dom ProjPMap1(g,[x,y]) and
A6:   z2 in dom ProjPMap1(g,[x,y]) and
A7:   |. z1-z2 .| < s;

A8:   X-section(dom g,[x,y])
       = {z where z is Element of REAL : [[x,y],z] in dom g}
        by MEASUR11:def 4;
A9:   z1 in X-section(dom g,[x,y]) & z2 in X-section(dom g,[x,y])
        by A5,A6,MESFUN12:def 3; then
A10:  ex z be Element of REAL st z = z1 & [[x,y],z] in dom g by A8;
A11:  ex z be Element of REAL st z = z2 & [[x,y],z] in dom g by A8,A9;
      reconsider xx = x, yy = y as Point of RNS_Real;
      reconsider zz1 = z1 as Point of RNS_Real by XREAL_0:def 1;
      reconsider zz2 = z2 as Point of RNS_Real by XREAL_0:def 1;
      reconsider p1 = [xx,yy,zz1], p2 = [xx,yy,zz2]
       as Point of [:[:RNS_Real,RNS_Real:],RNS_Real:];

A12:  zz1-zz2 = z1-z2 by DUALSP03:4;
      p1-p2 = [xx,yy,zz1] + [-xx,-yy,-zz2] by PRVECT_4:9; then
      p1-p2 = [xx-xx,yy-yy,zz1-zz2] by PRVECT_4:9; then
      p1-p2 = [0.RNS_Real,yy-yy,zz1-zz2] by RLVECT_1:15; then
      p1-p2 = [0.RNS_Real,0.RNS_Real,zz1-zz2] by RLVECT_1:15; then
      ||. p1-p2 .||
       = sqrt(||. 0.RNS_Real .||^2 +||. 0.RNS_Real .||^2 +||. zz1-zz2 .||^2)
        by PRVECT_4:9; then
      ||. p1-p2 .|| = ||. zz1-zz2 .|| by SQUARE_1:22; then
      ||. p1-p2 .|| = |. z1-z2 .| by A12,EUCLID:def 2; then
A13:  ||. f/.p1 - f/.p2 .|| < r by A4,A7,A2,A10,A11;

      ProjPMap1(g,[x,y]).z1 = g.([x,y],z1)
    & ProjPMap1(g,[x,y]).z2 = g.([x,y],z2) by A10,A11,MESFUN12:def 3; then
      ProjPMap1(g,[x,y]).z1 = f/.p1 & ProjPMap1(g,[x,y]).z2 = f/.p2
        by A2,A10,A11,PARTFUN1:def 6; then
      ProjPMap1(g,[x,y]).z1 - ProjPMap1(g,[x,y]).z2 = f/.p1 - f/.p2
        by DUALSP03:4;
      hence |. ProjPMap1(g,[x,y]).z1 - ProjPMap1(g,[x,y]).z2 .| < r
        by A13,EUCLID:def 2;
     end;
     hence thesis by A3;
    end;
    hence ProjPMap1(g,[x,y]) is uniformly_continuous by FCONT_2:def 1;
end;
