reserve T, T1, T2 for TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T,
  A1 for Subset of T1,
  A2 for Subset of T2,
  TM, TM1, TM2 for metrizable TopSpace,
  Am, Bm for Subset of TM,
  Fm, Gm for Subset-Family of TM,
  C for Cardinal,
  iC for infinite Cardinal;

theorem Th15:
  for T st for A st A is discrete holds card A c= C
  for F st F is open & not {} in F &
   for A,B st A in F & B in F & A <> B holds A misses B holds card F c= C
proof
  let T;
  assume
A1: for A st A is discrete holds card A c=C;
  let F such that
A2: F is open and
A3: not{} in F and
A4: for A,B st A in F & B in F & A<>B holds A misses B;
  per cases;
  suppose
    F is empty;
    hence thesis;
  end;
  suppose
A5: F is non empty;
   deffunc P(set)=the Element of $1;
     :: Choice !!! ???
A6: for x be set st x in F holds P(x) in [#]T
    proof
      let x be set;
      assume
A7:   x in F;
      then x<>{} by A3;
      then P(x) in x;
      hence thesis by A7;
    end;
    consider p be Function of F,[#]T such that
A8: for x be set st x in F holds p.x=P(x) from FUNCT_2:sch 11(A6);
    reconsider RNG=rng p as Subset of T;
    ex xx be object st xx in F by A5;
    then
A9: T is non empty by A3;
    then
A10: dom p=F by FUNCT_2:def 1;
    for x be Point of T st x in RNG ex G be Subset of T st G is open &
    RNG/\G={x}
    proof
      let x be Point of T;
      assume
A11:  x in RNG;
      then consider G be object such that
A12:  G in F and
A13:  p.G=x by A10,FUNCT_1:def 3;
      reconsider G as Subset of T by A12;
A14:  RNG/\G c={x}
      proof
        let y be object;
        assume
A15:    y in RNG/\G;
        then
A16:    y in G by XBOOLE_0:def 4;
        y in RNG by A15,XBOOLE_0:def 4;
        then consider z be object such that
A17:    z in F and
A18:    p.z=y by A10,FUNCT_1:def 3;
        reconsider z as set by TARSKI:1;
        y=P(z) by A8,A17,A18;
        then z meets G by A3,A16,A17,XBOOLE_0:3;
        then x=y by A4,A12,A13,A17,A18;
        hence thesis by TARSKI:def 1;
      end;
      take G;
      thus G is open by A2,A12;
      x=P(G) by A8,A12,A13;
      then x in RNG/\G by A3,A11,A12,XBOOLE_0:def 4;
      hence thesis by A14,ZFMISC_1:33;
    end;
    then
A19: card RNG c=C by A1,A9,TEX_2:31;
    for x1,x2 be object st x1 in dom p & x2 in dom p & p.x1=p.x2 holds x1=x2
    proof
      let x1,x2 be object such that
A20:  x1 in dom p and
A21:  x2 in dom p and
A22:  p.x1=p.x2;
      reconsider x1,x2 as set by TARSKI:1;
A23:  p.x2=P(x2) & x2<>{} by A3,A8,A21;
      p.x1=P(x1) & x1<>{} by A3,A8,A20;
      then x1 meets x2 by A22,A23,XBOOLE_0:3;
      hence thesis by A4,A10,A20,A21;
    end;
    then p is one-to-one by FUNCT_1:def 4;
    then card F c=card RNG by A10,CARD_1:10;
    hence thesis by A19;
  end;
end;
