reserve E, F, G,S,T,W,Y for RealNormSpace;
reserve f,f1,f2 for PartFunc of S,T;
reserve Z for Subset of S;
reserve i,n for Nat;

theorem Th16:
  for E,F,G be RealNormSpace,
      Z be Subset of E,
      T be Subset of F,
      u be PartFunc of E,F,
      v be PartFunc of F,G
   st u.:Z c= T
    & u is_continuous_on Z
    & v is_continuous_on T
  holds
     v*u is_continuous_on Z
proof
  let E,F,G be RealNormSpace,
      Z be Subset of E,
      T be Subset of F,
      u be PartFunc of E,F,
      v be PartFunc of F,G;
  assume that
  A1: u.:Z c= T and
  A2: u is_continuous_on Z and
  A3: v is_continuous_on T;

  set f = v*u;
  A4: Z c= dom u by A2,NFCONT_1:19;
  A5: T c= dom v by A3,NFCONT_1:19;
  A6: now
    let x be object;
    assume A7: x in Z;
    then u.x in u.:Z by A4,FUNCT_1:def 6;
    then u.x in T by A1;
    hence x in dom (v*u) by A4,A5,A7,FUNCT_1:11;
  end;

  for x0 be Point of E
  for r be Real st x0 in Z & 0 < r
  holds
    ex s be Real
    st 0 < s
     & for x1 be Point of E
       st x1 in Z & ||.(x1 - x0).|| < s
       holds ||.((f /. x1) - (f /. x0)).|| < r
  proof
    let x0 be Point of E;
    let r be Real;
    assume A8: x0 in Z & 0 < r;
    then u.x0 in u.:Z by A4,FUNCT_1:def 6;
    then u.x0 in T by A1;
    then u/.x0 in T by A4,A8,PARTFUN1:def 6;
    then consider t be Real such that
    A9: 0 < t
      & for y1 be Point of F
        st y1 in T & ||.y1 - u/.x0.|| < t
        holds ||.(v /. y1) - (v /.(u/.x0)).|| < r
        by A3,A8,NFCONT_1:19;

    consider s be Real such that
    A10: 0 < s
      & for x1 be Point of E
        st x1 in Z & ||.x1 - x0.|| < s
        holds ||.(u /. x1) - (u/.x0).|| < t
        by A2,A8,A9,NFCONT_1:19;

    take s;
    thus 0 < s by A10;
    let x1 be Point of E;

    assume that
    A11: x1 in Z and
    A12: ||.x1 - x0.|| < s;

    A13: ||.(u /. x1) - (u/.x0).|| < t by A10,A11,A12;
    u.x1 in u.:Z by A4,A11,FUNCT_1:def 6;
    then u.x1 in T by A1;
    then u/.x1 in T by A4,A11,PARTFUN1:def 6;
    then A14: ||.(v/.(u/.x1)) - (v/.(u/.x0)).|| < r by A9,A13;

    x1 in dom f by A6,A11;
    then A15: v /. (u /. x1) = f/.x1 by PARTFUN2:3;
    x0 in dom f by A6,A8;
    hence ||.(f /. x1) - (f /. x0).|| < r by A14,A15,PARTFUN2:3;
  end;
  hence thesis by A6,NFCONT_1:19,TARSKI:def 3;
end;
