reserve A,B,a,b,c,d,e,f,g,h for set;

theorem Th15:
  for G being strict irreflexive RelStr st G is trivial holds ComplRelStr G = G
proof
  let G be strict irreflexive RelStr;
  set CG = ComplRelStr G;
  assume
A1: G is trivial;
  per cases by A1,ZFMISC_1:131;
  suppose
A2: the carrier of G is empty;
    the InternalRel of CG = (the InternalRel of G)` \ id (the carrier of G
    ) by NECKLACE:def 8;
    then
A3: the InternalRel of CG = ({} \ {}) \ id {} by A2;
    the InternalRel of G = {} by A2;
    hence thesis by A3,NECKLACE:def 8;
  end;
  suppose
    ex x being object st the carrier of G = {x};
    then consider x being object such that
A4: the carrier of G = {x};
A5: the carrier of CG = {x} by A4,NECKLACE:def 8;
    the InternalRel of G c= [:{x},{x}:] by A4;
    then the InternalRel of G c= {[x,x]} by ZFMISC_1:29;
    then
A6: the InternalRel of G = {} or the InternalRel of G = {[x,x]} by ZFMISC_1:33;
A7: the InternalRel of G <> {[x,x]}
    proof
      assume not thesis;
      then
A8:   [x,x] in the InternalRel of G by TARSKI:def 1;
      x in the carrier of G by A4,TARSKI:def 1;
      hence contradiction by A8,NECKLACE:def 5;
    end;
    the InternalRel of CG = (the InternalRel of G)` \ id (the carrier of
    G) by NECKLACE:def 8;
    then the InternalRel of CG = ([:{x},{x}:] \ {}) \ id {x} by A4,A6,A7,
SUBSET_1:def 4;
    then the InternalRel of CG = {[x,x]} \ id {x} by ZFMISC_1:29;
    then the InternalRel of CG = {[x,x]} \ {[x,x]} by SYSREL:13;
    hence thesis by A4,A6,A7,A5,XBOOLE_1:37;
  end;
end;
