reserve x,x0,x1,x2,y,y0,y1,y2,r,r1,s,p,p1 for Real;
reserve z,z0 for Element of REAL 2;
reserve n,m,k for Element of NAT;
reserve Z for Subset of REAL 2;
reserve s1 for Real_Sequence;
reserve f,f1,f2 for PartFunc of REAL 2,REAL;
reserve R,R1,R2 for RestFunc;
reserve L,L1,L2 for LinearFunc;

theorem
  f is_partial_differentiable`1_on Z implies Z c= dom f & for z st z in
  Z holds f is_partial_differentiable_in z,1
proof
  set g = f|Z;
  assume
A1: f is_partial_differentiable`1_on Z;
  hence Z c= dom f;
  let z0 be Element of REAL 2;
  assume z0 in Z;
  then g is_partial_differentiable_in z0,1 by A1;
  then consider x0,y0 being Real such that
A2: z0 = <*x0,y0*> and
A3: ex N being Neighbourhood of x0 st N c= dom SVF1(1,g,z0) & ex L,R st
for x st x in N holds SVF1(1,g,z0).x - SVF1(1,g,z0).x0 = L.(x-x0) + R.(x-x0)
by Th9;
  consider N being Neighbourhood of x0 such that
A4: N c= dom SVF1(1,g,z0) and
A5: ex L,R st for x st x in N holds SVF1(1,g,z0).x - SVF1(1,g,z0).x0 = L
  .(x-x0) + R.(x-x0) by A3;
  consider L,R such that
A6: for x st x in N holds SVF1(1,g,z0).x - SVF1(1,g,z0).x0 = L.(x-x0) +
  R.(x-x0) by A5;
A7: for x st x in N holds SVF1(1,f,z0).x - SVF1(1,f,z0).x0 = L.(x-x0) + R.(
  x-x0)
  proof
    let x;
A8: for x st x in dom (SVF1(1,g,z0)) holds SVF1(1,g,z0).x = SVF1(1,f,z0). x
    proof
      let x;
      assume
A9:   x in dom (SVF1(1,g,z0));
      then
A10:  x in dom reproj(1,z0) by FUNCT_1:11;
A11:  reproj(1,z0).x in dom (f|Z) by A9,FUNCT_1:11;
      SVF1(1,g,z0).x = (f|Z).(reproj(1,z0).x) by A9,FUNCT_1:12
        .= f.(reproj(1,z0).x) by A11,FUNCT_1:47
        .= SVF1(1,f,z0).x by A10,FUNCT_1:13;
      hence thesis;
    end;
A12: x0 in N by RCOMP_1:16;
    assume
A13: x in N;
    then L.(x-x0) + R.(x-x0) = SVF1(1,g,z0).x - SVF1(1,g,z0).x0 by A6
      .= SVF1(1,f,z0).x - SVF1(1,g,z0).x0 by A4,A13,A8
      .= SVF1(1,f,z0).x - SVF1(1,f,z0).x0 by A4,A8,A12;
    hence thesis;
  end;
  for x st x in dom SVF1(1,g,z0) holds x in dom SVF1(1,f,z0)
  proof
    let x;
    dom (f|Z) = dom f /\ Z by RELAT_1:61;
    then
A14: dom (f|Z) c= dom f by XBOOLE_1:17;
    assume x in dom SVF1(1,g,z0);
    then x in dom reproj(1,z0) & reproj(1,z0).x in dom (f|Z) by FUNCT_1:11;
    hence thesis by A14,FUNCT_1:11;
  end;
  then for x be object st x in dom SVF1(1,g,z0) holds x in dom SVF1(1,f,z0);
  then dom SVF1(1,g,z0) c= dom SVF1(1,f,z0);
  then N c= dom SVF1(1,f,z0) by A4;
  hence thesis by A2,A7,Th9;
end;
