reserve U1,U2,U3 for Universal_Algebra,
  n,m for Nat,
  x,y,z for object,
  A,B for non empty set,
  h1 for FinSequence of [:A,B:];
reserve h1 for homogeneous quasi_total non empty PartFunc of
    (the carrier of U1)*,the carrier of U1,
  h2 for homogeneous quasi_total non empty PartFunc of
    (the carrier of U2)*,the carrier of U2;

theorem Th14:
  for p,q being 1-sorted-yielding FinSequence holds
    Carrier(p^q) = Carrier p ^ Carrier q
proof
  let p,q be 1-sorted-yielding FinSequence;
A1: len Carrier(p^q) = len(p^q) by Th13
    .= len p + len q by FINSEQ_1:22
    .= len Carrier p + len q by Th13
    .= len Carrier p + len Carrier q by Th13
    .= len(Carrier p ^ Carrier q) by FINSEQ_1:22;
  now
    let k be Nat;
    assume 1 <= k <= len Carrier(p^q);
    then k in dom Carrier(p^q) by FINSEQ_3:25;
    then A3: k in dom(p^q) by Def13;
    then consider R being 1-sorted such that
A4: R=(p^q).k & (Carrier(p^q)).k = the carrier of R by Def13;
    per cases by A3, FINSEQ_1:25;
    suppose A5: k in dom p;
      then consider R9 being 1-sorted such that
A6:   R9=p.k & (Carrier p).k = the carrier of R9 by Def13;
A7:   k in dom Carrier p by A5, Def13;
      R = R9 by A4, A5, A6, FINSEQ_1:def 7;
      hence (Carrier(p^q)).k = (Carrier p ^ Carrier q).k
        by A4, A6, A7, FINSEQ_1:def 7;
    end;
    suppose ex n being Nat st n in dom q & k = len p + n;
      then consider n being Nat such that
A8:   n in dom q & k = len p + n;
      consider R9 being 1-sorted such that
A9:   R9=q.n & (Carrier q).n = the carrier of R9 by A8, Def13;
A10:  n in dom Carrier q & k = len Carrier p + n
        by A8, Th13, Def13;
      R = R9 by A4, A8, A9, FINSEQ_1:def 7;
      hence (Carrier(p^q)).k = (Carrier p ^ Carrier q).k
        by A4, A9, A10, FINSEQ_1:def 7;
    end;
  end;
  hence thesis by A1, FINSEQ_1:def 18;
end;
